Mercurial > vba-clojure

     1 (ns com.aurellem.gb-driver

     2     (:import com.aurellem.gb.Gb)

     3     (:import java.io.File)

     4     (:import org.apache.commons.io.FileUtils)

     5     (:import (java.nio IntBuffer ByteOrder)))

     6 

     7 ;; Savestates

     8 (defrecord SaveState [data])

     9 

    10 (def ^:dynamic *save-state-cache*

    11   (File. "/home/r/proj/pokemon-escape/save-states/"))

    12 

    13 (def current-state (atom nil))

    14 

    15 (defn state-cache-file [name]

    16   (File. *save-state-cache* (str name ".sav")))

    17 

    18 (defn write-state!

    19   ([^SaveState name]

    20      (write-state! @current-state name))

    21   ([^SaveState save ^String name]

    22      (let [buffer (:data save)

    23            bytes (byte-array (.limit buffer))

    24            dest (state-cache-file name)]

    25        (.get buffer bytes)

    26        (FileUtils/writeByteArrayToFile dest bytes)

    27        (.rewind buffer)

    28        dest)))

    29 

    30 (defn read-state [name]

    31   (let [save (state-cache-file name)]

    32     (if (.exists save)

    33       (let [buffer (Gb/saveBuffer)

    34             bytes (FileUtils/readFileToByteArray save)]

    35         (.put buffer bytes)

    36         (.flip buffer)

    37         (SaveState. buffer)))))

    38 ;;;;;;;;;;;;;;;;

    39 

    40 ;; Gameboy management

    41 (Gb/loadVBA)

    42 

    43 (def yellow-rom-image

    44   (File. "/home/r/proj/pokemon-escape/roms/yellow.gbc"))

    45 

    46 (def yellow-save-file

    47   (File. "/home/r/proj/pokemon-escape/roms/yellow.sav"))

    48 

    49 (def on? (atom nil))

    50 

    51 (defn shutdown! [] (Gb/shutdown) (reset! on? false))

    52 

    53 (defn restart! []

    54   (shutdown!)

    55   (.delete yellow-save-file)

    56   (Gb/startEmulator (.getCanonicalPath yellow-rom-image))

    57   (reset! on? true))

    58 

    59 ;;; The first state!

    60 (defn gen-root! []

    61   (restart!)

    62   (let [state (SaveState. (Gb/saveState))]

    63     (write-state! state "root" ) state))

    64 

    65 (defn root []

    66   (if (.exists (state-cache-file "root"))

    67     (read-state "root")

    68     (gen-root!)))

    69 

    70 ;;;; Press Buttons

    71 

    72 (def button-code

    73   {;; main buttons

    74    :a         0x0001

    75    :b         0x0002

    76 

    77    ;; directional pad

    78    :r         0x0010

    79    :l         0x0020

    80    :u         0x0040

    81    :d         0x0080

    82 

    83    ;; meta buttons

    84    :select    0x0004

    85    :start     0x0008

    86 

    87    ;; pseudo-buttons

    88    :restart   0x0800 ; hard reset 

    89    :listen -1        ; listen for user input

    90    })

    91 

    92 (defn button-mask [buttons]

    93   (reduce bit-or 0x0000 (map button-code buttons)))

    94 

    95 (defn set-state! [^SaveState state]

    96   (assert (:data state) "Not a valid state!")

    97   (if (not @on?) (restart!))

    98   (if (not= state @current-state)

    99     (do 

   100       (Gb/loadState (:data state))

   101       (reset! current-state state))))

   102 

   103 (defn update-state []

   104   (reset! current-state

   105           (SaveState. (Gb/saveState))))

   106 

   107 (defn step

   108   ([^SaveState state buttons]

   109      (set-state! state)

   110      (Gb/step (button-mask buttons))

   111      (reset! current-state 

   112              (SaveState. (Gb/saveState))))

   113   ([^SaveState state]

   114      (step state [:listen]))

   115   ([] (step (if @current-state @current-state (root)))))

   116 

   117 (defn tick

   118   ([] (tick @current-state))

   119   ([^SaveState state]

   120      (set-state! state)

   121      (Gb/tick)

   122      (update-state)))

   123 

   124 (defn play

   125   ([^SaveState state n]

   126      (try

   127        (set-state! state)

   128        (dorun (dotimes [_ n]

   129                 (Thread/sleep 1)

   130                 (Gb/step)))

   131        (finally

   132              (update-state))))

   133   ([n]

   134      (play @current-state n)))

   135 

   136 (defn continue!

   137   ([state]

   138      (play state Integer/MAX_VALUE))

   139   ([]

   140     (continue! @current-state)))

   141 

   142 (defn play-moves

   143   ([moves [prev state]]

   144      (set-state! state)

   145      (dorun (map (fn [move] (step @current-state move)) moves))

   146      [(concat prev moves) @current-state]))

   147   

   148 ;;;;;;;;;;;

   149 

   150 

   151 ;;;;;;;;;;;;;;; CPU data

   152 

   153 (defn cpu-data [size arr-fn]

   154   (let [store (int-array size)]

   155     (fn get-data

   156       ([] (get-data @current-state))

   157       ([state]

   158          (set-state! state) (arr-fn store) store))))

   159 

   160 (defn write-cpu-data [size store-fn]

   161   (fn store-data

   162     ([state new-data]

   163        (set-state! state)

   164        (let [store (int-array new-data)]

   165          (assert (= size (count new-data)))

   166          (store-fn store)

   167          (update-state)))

   168     ([new-data]

   169        (store-data @current-state new-data))))

   170     

   171 

   172 (def memory

   173   (cpu-data Gb/GB_MEMORY #(Gb/getMemory %)))

   174 

   175 (def ram

   176   (cpu-data Gb/RAM_SIZE #(Gb/getRAM %)))

   177 

   178 (def rom 

   179   (cpu-data Gb/ROM_SIZE #(Gb/getROM %)))

   180 

   181 (def working-ram 

   182   (cpu-data Gb/WRAM_SIZE #(Gb/getWRAM %)))

   183 

   184 (def video-ram 

   185   (cpu-data Gb/VRAM_SIZE #(Gb/getVRAM %)))

   186 

   187 (def registers

   188   (cpu-data Gb/NUM_REGISTERS #(Gb/getRegisters %)))

   189 

   190 (def write-memory!

   191   (write-cpu-data Gb/GB_MEMORY #(Gb/writeMemory %)))

   192 

   193 (def write-registers!

   194   (write-cpu-data Gb/NUM_REGISTERS #(Gb/writeRegisters %)))

   195 

   196 ;;;;;  Registers  ;;;;;;;;;;;;;;;;;;;;;;;;;;;

   197 

   198 (defmacro gen-get-set-register [name index]

   199   (let [name-bang (symbol (str name "!"))]

   200     `(do

   201        (defn ~name

   202          ~(str "Retrieve the " name " register from state, or "

   203                "from @current-state if state is absent.")

   204          ([state#]

   205             (nth (registers state#) ~index))

   206          ([]

   207             (~name @current-state)))

   208        (defn ~name-bang

   209          ~(str "Set the " name " register for state, or "

   210                "for @current-state if state is absent.")

   211          ([state# new-register#]

   212             (set-state! state#)

   213             (let [registers# (registers state#)]

   214               (aset registers# ~index new-register#)

   215               (Gb/writeRegisters registers#)

   216               (update-state)))

   217          ([new-register#]

   218             (~name-bang @current-state new-register#))))))

   219 

   220 ;; 16 bit registers

   221 (gen-get-set-register PC 0)

   222 (gen-get-set-register SP 1)

   223 (gen-get-set-register AF 2)

   224 (gen-get-set-register BC 3)

   225 (gen-get-set-register DE 4)

   226 (gen-get-set-register HL 5)

   227 (gen-get-set-register IFF 6)

   228 

   229 ;; 8 bit registers

   230 (gen-get-set-register DIV 7)

   231 (gen-get-set-register TIMA 8)

   232 (gen-get-set-register TMA 9)

   233 (gen-get-set-register IF 11)

   234 (gen-get-set-register LCDC 12)

   235 (gen-get-set-register STAT 13)

   236 (gen-get-set-register SCY 14)

   237 (gen-get-set-register SCX 15)

   238 (gen-get-set-register LY 16)

   239 (gen-get-set-register DMA 18)

   240 (gen-get-set-register WY 19)

   241 (gen-get-set-register WX 20)

   242 (gen-get-set-register VBK 21)

   243 (gen-get-set-register HDMA1 22)

   244 (gen-get-set-register HDMA2 23)

   245 (gen-get-set-register HDMA3 24)

   246 (gen-get-set-register HDMA4 25)

   247 (gen-get-set-register HDMA5 26)

   248 (gen-get-set-register SVBK 27)

   249 (gen-get-set-register IE 28)

   250                             

   251 ;;;;;;;;;;;;;;;

   252 

   253 (defmacro defn-memo

   254   [& forms]

   255   (let [fun-name (first forms)]

   256     `(do

   257        (defn ~@forms)

   258        (alter-var-root (var ~fun-name) memoize))))

   259
author	Robert McIntyre <rlm@mit.edu>
date	Sat, 17 Mar 2012 21:32:29 -0500
parents	bcb5c41626b4
children	718abf3bec8a