(ns com.aurellem.run.bootstrap-1

   (:use (com.aurellem.gb saves gb-driver util constants

                          items vbm characters money))

   (:use (com.aurellem.run util title save-corruption bootstrap-0))

   (:use (com.aurellem.exp item-bridge))

   (:import [com.aurellem.gb.gb_driver SaveState]))

 

 (defn pc-item-writer-program

   []

   (let [limit 201

         [target-high target-low] (disect-bytes-2 pokemon-list-start)]

     (flatten

      [[0x00  ;; (item-hack) set increment stack pointer no-op

        0x1E  ;; load limit into E

        limit

        0x3F  ;; (item-hack) set carry flag no-op

 

        ;; load 2 into C.

        0x0E   ;; C == 1 means input-first nybble

        0x04   ;; C == 0 means input-second nybble

 

        0x21 ;; load target into HL

        target-low

        target-high

        0x37 ;; (item-hack) set carry flag no-op

 

        0x00 ;; (item-hack) no-op

        0x37 ;; (item-hack) set carry flag no-op

        

        0x00 ;; (item-hack) no-op

        0xF3 ;; disable interrupts

        ;; Input Section

 

        0x3E ;; load 0x20 into A, to measure buttons

        0x10 

 

        0x00 ;; (item-hack) no-op

        0xE0 ;; load A into [FF00]

        0x00

 

        0xF0 ;; load 0xFF00 into A to get

        0x00 ;; button presses

        

        0xE6

        0x0F ;; select bottom four bits of A

        0x37 ;; (item-hack) set carry flag no-op

 

        0x00 ;; (item-hack) no-op

        0xB8 ;; see if input is different (CP A B)

 

        0x00 ;; (item-hack) (INC SP)

        0x28 ;; repeat above steps if input is not different

        ;; (jump relative backwards if B != A)

        0xED ;; (literal -19) (item-hack) -19 == egg bomb (TM37)

 

        0x47 ;; load A into B

        

        0x0D ;; dec C

        0x37 ;; (item-hack) set-carry flag

        ;; branch based on C:

        0x20 ;; JR NZ

        23 ;; skip "input second nybble" and "jump to target" below

        

        ;; input second nybble

 

        0x0C ;; inc C

        0x0C ;; inc C

 

        0x00 ;; (item-hack) no-op

        0xE6 ;; select bottom bits

        0x0F

        0x37 ;; (item-hack) set-carry flag no-op

 

        0x00 ;; (item-hack) no-op

        0xB2 ;; (OR A D) -> A

 

        0x22 ;; (do (A -> (HL)) (INC HL))

 

        0x1D ;; (DEC E)

 

        0x00 ;; (item-hack) 

        0x20 ;; jump back to input section if not done

        0xDA ;; literal -36 == TM 18 (counter)

        0x01 ;; (item-hack) set BC to literal (no-op)

 

        ;; jump to target

        0x00  ;; (item-hack) these two bytes can be anything.

        0x01 

 

        0x00   ;; (item-hack) no-op

        0xBF   ;; (CP A A) ensures Z

        

        0xCA   ;; (item-hack) jump if Z

        target-low

        target-high

        0x01   ;; (item-hack) will never be reached.

        

        ;; input first nybble

        0x00

        0xCB

        0x37  ;; swap nybbles on A

 

        0x57  ;; A -> D

 

        0x37  ;; (item-hack) set carry flag no-op

        0x18  ;; relative jump backwards

        0xCD  ;; literal -51 == TM05; go back to input section

        0x01  ;; (item-hack) will never reach this instruction

 

        ]

       (repeat 8 [0x00 0x01]);; these can be anything

 

       [;; jump to actual program

        0x00

        0x37  ;; (item-hack) set carry flag no-op

 

        0x2E  ;; 0x3A -> L

        0x3A

 

 

        0x00  ;; (item-hack) no-op

        0x26  ;; 0xD5 -> L

        0xD5  

        0x01  ;; (item-hack) set-carry BC

 

        0x00  ;; (item-hack) these can be anything

        0x01  

 

        0x00

        0xE9 ;; jump to (HL)

        ]])))

 

 (defn print-desired-item-layout []

   (clojure.pprint/pprint

    (raw-inventory->inventory (pc-item-writer-program))))

 

 (defn pc-item-writer-state []

     (-> (read-state "bootstrap-init")

       (set-memory pc-item-list-start 50)

       (set-memory-range

        map-function-address-start

        [0x8B 0xD5])

       (set-memory-range

        (inc pc-item-list-start)

        (pc-item-writer-program))))

 

 (defn test-pc-item-writer []

   (let [orig (read-state "pc-item-writer")]

     (-> orig

     (print-listing 0xD162 (+ 0xD162 20))

     (run-moves (reduce concat

                 (repeat 10 [[:a :b :start :select] []])))

     ((fn [_] (println "===========") _))

     (print-listing 0xD162 (+ 0xD162 20)))))

 

 (defn close-all-menus [[moves state :as script]]

   (loop [s script]

     (let [depth (current-depth (second (do-nothing 50 s)))]

       (println "depth" depth)

       (if (= depth 1)

         s

         (recur (close-menu s))))))

 

 (defn-memo name-rival

   ([] (name-rival (to-rival-name)))

   ([script]

      (->> script

           (first-difference [] [:a] AF)

           (first-difference [] [:r] DE)

           (play-moves

            [[]

             [] [] [:r] [] [:d] [:a]           ;; L

             [:r] [] [:r] [] [:r] [] [:r] [] 

             [:r] [] [:d] [] [:d] [:a]         ;; [PK]

             [:d] [] [:r] [:a]

             ]))))

 

 (defn-memo to-room-pc

   ([] (to-room-pc (name-rival)))

   ([script]

      (->> script

           finish-title

           (walk [← ← ↑ ← ↑ ↑ ↑]))))

 

 ;; (defn wait-for-quantity

 ;;   [[moves state :as script]]

 ;;   (if (not= (item-quantity-selected state) 1)

 ;;     (repeat-until-different [] item-quantity-selected script)

 ;;     script))

 

 ;; TODO use this:

 ;;(wait-until (partial set-cursor-relative 1))

 

 ;; (defn wait-for-cursor

 ;;   [[moves state :as script]]

 ;;   (if (not= (list-offset state) 0)

 ;;     (repeat-until-different [] list-offset script)

 ;;     script))

 

 (defn deposit-held-item [n quantity [moves state :as script]]

   (let [total-quantity (second (nth-item state n))]

     (println "total-quantity" total-quantity)

     (->> script

          (set-cursor n)

          (select-menu-entry 1)

          ;;(wait-for-quantity)

          (set-quantity total-quantity quantity)

          (delayed-difference [] [:a] 100 #(search-string % "stored"))

          (scroll-text))))

 

 (defn sell-held-item [n quantity [moves state :as script]]

   (let [total-quantity (second (nth-item state n))]

     (->> script

          ;;(wait-for-cursor)  ;; when selling, the cursor always

          (set-cursor n)     ;; returns to the top of the list.

          (select-menu-entry 1)

          ;;(wait-for-quantity)

          (set-quantity total-quantity quantity)

          (delayed-difference [] [:a] 100 current-depth)

          (play-moves (repeat 20 [:b]))

          (delayed-difference [] [:a] 100 #(search-string % "What"))

          )))

 

 (defn widthdraw-pc-item [n quantity [moves state :as script]]

   (let [total-quantity (second (nth-pc-item state n))]

     (->> script

          (set-cursor n)

          (select-menu-entry 1)

          ;;(wait-for-quantity)

          (set-quantity total-quantity quantity)

          (delayed-difference [] [:a] 100 #(search-string % "Withdrew"))

          (scroll-text))))

 

 (defn toss-held-item [n quantity [moves state :as script]]

   (let [total-quantity (second (nth-item state n))]

     (->> script

          (set-cursor n)

          (select-menu-entry 1)

          (set-cursor-relative 1)

          (select-menu-entry -1)

          ;;(wait-for-quantity)

          (set-quantity total-quantity quantity)

          (play-moves [[:a]])

          (scroll-text)

          (delayed-difference [] [:a] 100 #(search-string % "Threw"))

          (scroll-text)

          )))

 

 (defn buy-item [n quantity [moves state :as script]]

   (->> script

        (set-cursor n)

        (purchase-item quantity)))

 

 (defn switch-items [item-fn idx-1 idx-2 script]

   (->> script

        (wait-until select-menu-entry)

        (set-cursor idx-1)

        (wait-until select-menu-entry)

        (play-moves [[][:select][]])

        (set-cursor idx-2)

        (delayed-difference [] [:select] 100

                            #(item-fn % (list-offset %)))))

 

 (def switch-pc-items (partial switch-items nth-pc-item))

 (def switch-held-items (partial switch-items nth-item))

 

 (defn combine-pc-items [idx-1 script]

   (->> script

        (switch-pc-items idx-1 (inc idx-1))))

 

 (def desired-zero-quantities

   (map second (filter (comp (partial = 0) first)

                       (partition 2 (pc-item-writer-program)))))

 

 (defn-memo bootstrap-corrupt-save

   ([] (bootstrap-corrupt-save (to-room-pc)))

   ([script]

    (->> script

         (do-save-corruption 3)

         (corrupt-item-list 0)

         close-all-menus)))

 

 (defn-memo prepare-celadon-warp

   ([] (prepare-celadon-warp (bootstrap-corrupt-save)))

   ([script]

      (->> script

           (activate-start-menu)

           (set-cursor-relative 1)

           (select-menu-entry)

           ;; vastly increase text speed while we're here.

           (switch-held-items 21 27)

           (toss-held-item 35 0xFA)

           (close-all-menus))))

 

 (defn-memo begin-initial-deposits

   ([] (begin-initial-deposits

        (prepare-celadon-warp)))

   ([script]

      (->> script

           (first-difference [] [:a] AF)

           (scroll-text)

           (set-cursor 1)

           select-menu-entry)))

 

 (defn-memo initial-deposits

   ([] (initial-deposits (begin-initial-deposits)))

   ([script]

      (->> script

           (deposit-held-item 0 0x1)

           ((fn [script]

              (reduce 

               (fn [script item] (deposit-held-item item 0xFF script))

               script

               (range 3 (+ 13 3)))))

           close-all-menus)))

 

 

 ;;0 -- 256

 ;;1 -- 254

 ;;2 -- 254

 ;;3 -- 255

 

 (defn activate-home-pc

   [script]

   (->> script

        (delayed-difference [] [:a]

                            200 first-character)

        (scroll-text)))

 

 (defn-memo restore-items

   ([] (restore-items (initial-deposits)))

   ([script]

      (->> script

           activate-home-pc

           (select-menu-entry)

           (widthdraw-pc-item 0 1)

           ;;(widthdraw-pc-item 0 99)

           ;;(widthdraw-pc-item 1 1)

           (widthdraw-pc-item 13 255)

           (close-all-menus))))

 

 (defn-memo to-celadon

   ([] (to-celadon (restore-items)))

   ([script]

      (->> script

           (walk [→ → → → → → → ↑

                  ↓ ↓ ↓ ↓ ↓ ← ← ← ←

                  ↓ ↓]))))

 

 

 ;; celadon store inventory

 

 ;; Floor 2

 ;;=====================================

 ;; Great Ball        TM32 (double-team)

 ;; Super Potion      TM33 (reflect)

 ;; Revive            TM02 (razor-wind)

 ;; Super Repel       TM07 (horn-drill)

 ;; Antidote          TM37 (egg-bomb)

 ;; Burn Heal         TM01 (mega-punch)

 ;; Ice Heal          TM05 (mega-kick)

 ;; Awakening         TM09 (take-down)

 ;; Parlyz Heal       TM17 (submission)

 

 

 ;; Floor 3

 ;;=====================================       

 ;; TM18 (counter)

 

 

 ;; Floor 4

 ;;=====================================

 ;; Poke Doll

 ;; Fire Stone

 ;; Thunder Stone

 ;; Water Stone

 ;; Leaf Stone

 

 ;; Floor 5

 ;;=====================================

 ;; X Accuracy         HP UP

 ;; Guard Spec.        Protein

 ;; Dire Hit           Iron

 ;; X Attack           Carbos

 ;; X Defend           Calcium

 ;; X Speed            

 ;; X Special

 

 ;; Roof

 ;;=====================================

 ;; Fresh Water        TM13 (ice-beam)

 ;; Soda Pop           TM48 (rock-slide)

 ;; Lemonade :)        TM49 (tri-attack)

 

 

 (defn-memo go-to-floor-two

   ([] (go-to-floor-two (to-celadon)))

   ([script]

      (->> script

           (walk [↑ → → → → → → → → → → →

                  ↑ ↑ ↑ ↑ ↑ ↑

                  ← ← ← ← 

                  ↓ ↓ ↓

                  ← ←])

           (first-difference [] ↑ AF))))

 

 (defn talk

   "Assumes that you are facing something that initiates text and

    causes it to do so."

   [script]

   (->> script

        (delayed-difference [] [:a] 100

                            first-character)))

 

 (defn-memo get-money-floor-two

   ([] (get-money-floor-two (go-to-floor-two)))

   ([script]

      (->> script

           talk

           (set-cursor 1)

           (select-menu-entry)

           (sell-held-item 0 1)

           (sell-held-item 0 1)

           (close-menu))))

 

 (defn-memo floor-two-TMs

   ([] (floor-two-TMs (get-money-floor-two)))

   ([script]

      (->> script

           (set-cursor 0)

           (select-menu-entry)

           (buy-item 2 98)  ;; TM02 (razor-wind)

           (buy-item 4 71)  ;; TM37 (doubleteam)

           (buy-item 5 63)  ;; TM01 (mega-punch)

           (buy-item 6 1)   ;; TM05 (mega-kick)

           (buy-item 7 56)  ;; TM09 (take-down)

           (close-menu))))

 

 (defn end-shop-conversation

   [script]

   (->> script

        (wait-until scroll-text [:b])

        (play-moves [[] [:b]])

        close-menu))

 

 (defn-memo floor-two-more-money

   ([] (floor-two-more-money (floor-two-TMs)))

   ([script]

      (->> script

           (set-cursor 1)

           (select-menu-entry)

           (sell-held-item 0 1)

           (sell-held-item 0 1)

           close-menu

           end-shop-conversation)))

 

 (defn turn [direction script]

   (->> script

        (first-difference [] direction AF)))

 

 (defn-memo floor-two-items

   ([] (floor-two-items (floor-two-more-money)))

   ([script]

      (->> script

           (walk [←])

           (turn ↑)

           talk

           select-menu-entry

           (buy-item 5 12)  ;; burn heal

           (buy-item 6 55)  ;; ice heal

           (buy-item 7 4)   ;; awakening

           (buy-item 8 99)  ;; parlyz heal

           (buy-item 8 55)  ;; parlyz heal

           close-menu

           end-shop-conversation)))

 

 (defn-memo go-to-floor-three

   ([] (go-to-floor-three (floor-two-items)))

   ([script]

      (->> script

           (walk [→ → → → → → → → → → ↑ ↑ ↑

                    → ↑]))))

 (defn-memo get-TM18

   ([] (get-TM18 (go-to-floor-three)))

   ([script]

      (->> script

           (walk [↓ ↓])

           talk

           (scroll-text 3)

           end-text)))

 

 (defn-memo go-to-floor-four

   ([] (go-to-floor-four (get-TM18)))

   ([script]

      (->> script

           (walk [← ← ← ← ↑ ↑

                  ↓ ← ← ↓ ↓ ↓

                  ← ← ← ← ←])

           (turn ↓))))

 

 (defn-memo floor-four-items

   ([] (floor-four-items (go-to-floor-four)))

   ([script]

      (->> script

           talk

           select-menu-entry

           (buy-item 1 23)  ;; Fire Stone

           (buy-item 2 98)  ;; Thunder Stone

           (buy-item 3 29)  ;; Water Stone

           close-menu

           end-shop-conversation)))

 

 (defn-memo go-to-floor-five

   ([] (go-to-floor-five (floor-four-items)))

   ([script]

      (->> script

           (walk [→ → → → → →

                  ↑ ↑ ↑

                  → → → → → ↑ ;; leave floor four

                  ↓ ← ← ← ← ← ← ← ←

                  ↓ ↓ ↓ ← ← ← ]);; go to five's clerk

           (turn ↑))))

                 

 (defn-memo floor-five-items

   ([] (floor-five-items (go-to-floor-five)))

   ([script]

      (->> script

           talk

           select-menu-entry

           (buy-item 0 58)   ;; X-Accuracy

           (buy-item 1 99)   ;; Guard Spec.

           (buy-item 1 24)   ;; Guard Spec.

           close-menu

           end-shop-conversation)))

 

 (defn-memo go-to-roof

   ([] (go-to-roof (floor-five-items)))

   ([script]

      (->> script

           (walk [→ → → → ↑ ↑ ↑ → → → ↑ ;; leave floor five

                  ↓ ← ← ←]) ;; walk to vending machine

           (turn ↑))))

 

 (defn buy-drink

   "Assumes you're in front of the vending machine. Buys the indicated

    drink."

   [n script]

   (->> script

        (do-nothing 20)

        (play-moves [[:a][:a]])

        scroll-text

        (set-cursor n)

        select-menu-entry

        close-menu))

 

 (defn-memo roof-drinks

   ([] (roof-drinks (go-to-roof)))

   ([script]

      (->> script

           (buy-drink 0) ;; fresh water (for TM13)

           ;; buy 16 lemonades

           ;; LEMONADE is the best item <3  :)

           (multiple-times 16 (partial buy-drink 2)))))

 

 (defn-memo get-TM13

   ([] (get-TM13 (roof-drinks)))

   ([script]

      (->> script

           ;;(walk [← ← ← ← ← ← ↓])

           (walk [↓ ↓ ↓ ← ← ← ← ← ←])

           (play-moves [[][][][][:a][:a][]])

           (scroll-text 3)

           select-menu-entry

           select-menu-entry

           (scroll-text 6)

           close-menu)))

 

 (defn-memo to-celadon-poke-center

   ([] (to-celadon-poke-center (get-TM13)))

   ([script]

      (->> script

           ;;(walk [↑ → → → → → → → → → ↑])       ; leave roof

           (walk [→ → → → → → → → → ↑ ↑ ↑ ↑])

           (walk [↓ ← ← ← ← ↓ ↓ ↓ ← ← ← ← ← 

                  ↑ ↑ ↑ ← ← ↑])                 ; to elevator

                  

           (walk [→ → ↑ ↑])                     ; to controls

           talk

           select-menu-entry                    ; to floor 1

           (walk [↓ ↓ ← ←])

           (walk [↓ → ↓ ↓ ↓ ↓ ↓ ↓])             ; leave store

           (walk [↓ → → → → → → → → → → ↑ ↑])

           (walk (repeat 23 →))

           (walk [↑ ↑ ↑ ↑])                     ; enter poke center

           (walk [↑ ↑ ↑ → → → → → → → → → →])   ; to computer

           (turn ↑))))

 

 (defn activate-rlm-pc [script]

   (->> script

        talk

        scroll-text

        ;;wait-for-cursor

        (set-cursor 1)

        select-menu-entry

        (scroll-text 2)))

 

 (defn begin-deposit [script]

   (->> script

        (set-cursor 1)

        select-menu-entry))

 

 (defn begin-withdraw [script]

   (->> script

        (set-cursor 0)

        (select-menu-entry)))

 

 (defn deposit-held-item-named

   [item-name quantity [moves state :as script]]

   (let [index (count

                (take-while

                 (fn [[name quant]]

                   (or (not= name item-name)

                       (< quant quantity)))

                   (inventory state)))]

     (println "index" index)

     (deposit-held-item index quantity script)))

 

 (defn open-held-items

   [script]

   (->> script

        select-menu-entry))

 

 (defn to-held-items

   [script]

   (->> script

        close-menu

        close-menu

        end-text;;; grr

        

        activate-start-menu

        open-held-items))

 

 (defn toss-pc-item [n quantity  [moves state :as script]]

   (let [total-quantity (second (nth-pc-item state n))]

     (->> script

          (set-cursor n)

          (select-menu-entry 1)

          (set-quantity total-quantity quantity)

          (delayed-difference [] [:a] 100 #(search-string % "Is"))

          (scroll-text)

          select-menu-entry

          (scroll-text))))

 

 (defn-memo hacking-1

   ([] (hacking-1 (to-celadon-poke-center)))

   ([script]

      (->> script

           activate-rlm-pc

           begin-deposit

           (deposit-held-item-named 0x00           30)

           (deposit-held-item-named :TM01          63)

           (deposit-held-item-named :awakening      4)

           (deposit-held-item-named :thunderstone  98)

           (deposit-held-item-named :TM09          55)

           (deposit-held-item-named 0x00           55))))

 

 (defn-memo hacking-2

   ([] (hacking-2 (hacking-1)))

   ([script]

      (->> script

           (to-held-items)

           (toss-held-item 0 166) ;; discard cruft

           close-menu

           close-menu)))

 

 (defn-memo hacking-3

   ([] (hacking-3 (hacking-2)))

   ([script]

      (->> script

           activate-rlm-pc

           begin-withdraw

           (widthdraw-pc-item 0 99)

           (widthdraw-pc-item 0 1)

           (widthdraw-pc-item 2 0xFE)

           (widthdraw-pc-item 3 0xFE)

           close-menu)))

           

 (defn-memo hacking-4

   ([] (hacking-4 (hacking-3)))

   ([script]

      (->> script

           begin-deposit

           (deposit-held-item 19 243)

           (deposit-held-item-named :lemonade 16)

           (deposit-held-item 18 224))))

           

 (defn-memo hacking-5

   "clean out the held-item list again"

   ([] (hacking-5 (hacking-4)))

   ([script]

      (->> script

           (to-held-items)

           (toss-held-item 18 30)

           (toss-held-item 17 1)

           close-menu

           close-menu)))

 

 (defn-memo hacking-6

   ([] (hacking-6 (hacking-5)))

   ([script]

      (->> script

           activate-rlm-pc

           begin-withdraw

           (widthdraw-pc-item 4 0xFE)

           (widthdraw-pc-item 5 0xFE)

           (widthdraw-pc-item 6 0xFE)

           close-menu)))

 

 (defn-memo hacking-7

   ([] (hacking-7 (hacking-6)))

   ([script]

      (->> script

           begin-deposit

           (deposit-held-item 19 240)

           (deposit-held-item 18 230)

           (deposit-held-item-named :parlyz-heal 55)

           (deposit-held-item 17 184)

           (deposit-held-item 17 40)

           (deposit-held-item-named :TM37 71)

           (deposit-held-item-named :ice-heal 55)

           (deposit-held-item-named :fire-stone 23)

           (deposit-held-item-named :burn-heal 12)

           ;; as a special case, /don't/ close the menu.

           )))

 

 (defn-memo hacking-8

   "Clear cruft away from held item list."

   ([] (hacking-8 (hacking-7)))

   ([script]

      (->> script

           to-held-items

           (toss-held-item 15 1)

           (toss-held-item 14 1)

           (toss-held-item 13 1)

           close-menu

           close-menu)))

 

 (defn-memo hacking-9

   ([] (hacking-9 (hacking-8)))

   ([script]

      (->> script

           activate-rlm-pc

           begin-withdraw

           (widthdraw-pc-item 7 0xFE)

           (widthdraw-pc-item 8 0xFC)

           (widthdraw-pc-item 8 1)

           (widthdraw-pc-item 8 1)

           (widthdraw-pc-item 9 0xFE)

           (multiple-times

            7

            (partial combine-pc-items 2))

           close-menu)))

           

 (defn-memo hacking-10

   ([] (hacking-10 (hacking-9)))

   ([script]

      (->> script

           begin-deposit

           (deposit-held-item 17 230)

           (deposit-held-item-named :parlyz-heal 55)

           (deposit-held-item 14 178)

           (deposit-held-item-named :water-stone 29)

           (deposit-held-item 14 32)

           (deposit-held-item-named :TM18 1)

           (deposit-held-item 13 1)

           (deposit-held-item 13 191)

           (deposit-held-item-named :TM02 98)

           (deposit-held-item-named :TM09 1)

           close-menu)))

 

 (defn-memo hacking-11

   ([] (hacking-11 (hacking-10)))

   ([script]

      (->> script

           begin-withdraw

           (widthdraw-pc-item 3 0xFE)

           (widthdraw-pc-item 4 0xFE)

           (widthdraw-pc-item 5 1)

           (widthdraw-pc-item 5 1)

           (widthdraw-pc-item 5 1)

           (widthdraw-pc-item 5 0xFB)

           (multiple-times

            3

            (partial combine-pc-items 2))

           close-menu)))

 

 (defn-memo hacking-12

   ([] (hacking-12 (hacking-11)))

   ([script]

      (->> script

           begin-deposit

           (deposit-held-item 18 203)

           (deposit-held-item-named :guard-spec 87)

           (deposit-held-item-named :guard-spec 24)

           (deposit-held-item-named :TM05 1)

           (multiple-times

            8

            (partial deposit-held-item 14 1))

           (deposit-held-item 14 55)

           (deposit-held-item-named :x-accuracy 58)

           (deposit-held-item 14 38)

           (deposit-held-item-named :TM13 1)

           (deposit-held-item 13 1)

           (deposit-held-item 13 233)

           close-menu)))

        

 (defn-memo hacking-13

   ([] (hacking-13 (hacking-12)))

   ([script]

      (->> script

           (set-cursor-relative 1)

           (select-menu-entry)

           (toss-pc-item 1 1)

           (toss-pc-item 0 156)

           (toss-pc-item 0 11))))

 

 (defn confirm-pattern []

   (let [start-address (inc pc-item-list-start)

         target-pattern (pc-item-writer-program)

         actual-pattern

         (subvec (vec (memory (second (hacking-13))))

                 start-address

                 (+ start-address (count target-pattern)))]

     (println target-pattern)

     (println actual-pattern)

     (= target-pattern actual-pattern)))

 

 (defn-memo go-to-mansion-for-the-lulz

   ([] (go-to-mansion-for-the-lulz (hacking-13)))

   ([script]

      (->> script

           close-menu

           close-menu

           end-text ;;grr

           (walk [↓ ← ← ← ← ← ← ← ← ← ↓ ↓ ↓])

           (walk (repeat 17 ←))

           (walk [↑ → → → → ↑ ↑ ↑ ↑ ↑ ↑ ↑ ↑ ↑ ↑])

           (walk [↓ ← ↑])

           (walk [↓ ↓ ↓ ↓ ↓ ↓ ↓

                  ← ← ← ← ↑ ↑ ↑ ← ↑])

           (talk)

           (scroll-text 2)

           (do-nothing 100)

           close-menu)))

 

 (defn-memo launch-bootstrap-program

   ([] (launch-bootstrap-program

        (go-to-mansion-for-the-lulz)))

   ([script]

      (->> script

           ;; must corrupt item list again by switching pokemon

           activate-start-menu    ;; \

           (set-cursor 0)         ;; |

           select-menu-entry      ;; |

           select-menu-entry      ;; |

           (set-cursor 1)         ;; | -- switch 9th pokemon

           select-menu-entry      ;; |    with 4th pokemon

           (set-cursor 3)         ;; |

           select-menu-entry      ;; |

           close-menu             ;; /

           ;; now, open items and set map-function to

           ;; the program inside the item-computer.

           (set-cursor 1)

           (select-menu-entry)

           (toss-held-item 22 12)

           (switch-held-items 22 40)

           close-all-menus)))

 

 (defn regen-control-checkpoint!

   [] (write-script! (launch-bootstrap-program) "control-checkpoint"))

                     

 (defn control-checkpoint []

   (read-script "control-checkpoint"))

 

 (defn no-consecutive-repeats? [seq]

   (not (contains? (set(map - seq (rest seq))) 0)))

 

 (defn byte->nybbles [byte]

   [(bit-shift-right byte 4) (bit-and byte 0x0F)])

 

 (defn bootstrap-pattern

   "Given an assembly sequence, generate the keypresses required to

    create that sequence in memory using the pc-item-writer

    program. The assembly must not have any consecutive repeating

    nybbles."

   [assembly]

   (let [nybbles (flatten (map byte->nybbles assembly))

         moves (map (comp buttons (partial - 15)) nybbles)

         header (map buttons

                     (concat (repeat

                              50

                              (- 15 (first nybbles)))

                             [(first nybbles)]))

         tail (map buttons

                   (take

                    (- 201 (count moves))

                    (interleave (repeat 100 (last nybbles))

                                (repeat 1000 (- 15 (last nybbles))))))]

     (assert (no-consecutive-repeats? nybbles))

     (concat header moves tail)))

 

 (def increasing-pattern [0x01 0x23 0x45 0x67 0x89 0xAB 0xCD 0xEF])

 

 (defn test-pattern-writing

   ([] (test-pattern-writing increasing-pattern))

   ([pattern]

      (let [moves (bootstrap-pattern pattern)

            pattern-insertion

            (->> (launch-bootstrap-program)

                 (play-moves

                  (take 100 moves)))]

        (println "Input Pattern:")

        (apply println  (map #(format "0x%02X" %) pattern))

        (println "\nMemory Listing:")

        (print-listing (second pattern-insertion)

                       0xD162 (+ 0xD162 (count pattern)))

        (= (subvec (vec (memory (second pattern-insertion)))

                        0xD162 (+ 0xD162 (count pattern)))

           pattern))))