#+title: Notes on Deconstructing Pokemon Yellow

 #+author: Dylan Holmes

 #+email: rlm@mit.edu

 #+description:

 #+keywords:

 #+SETUPFILE: ../../aurellem/org/setup.org

 #+INCLUDE: ../../aurellem/org/level-0.org

 #+BABEL: :exports both :noweb yes :cache no :mkdirp yes

 

 # about map headers http://datacrystal.romhacking.net/wiki/Pokemon_Red/Blue:Notes

 # map headers Yellow http://www.pokecommunity.com/archive/index.php/t-235311.html

 # pokedollar: U+20B1

 * Introduction

 

 

 ** COMMENT Getting linguistic data: names, words, etc.

 

 Some of the simplest data 

 

 

 One of the simplest data structures in the Pok\eacute{} ROM is an

 unbroken list of strings that either (a) all have a specific length,

 or (b) are all separated by the same character.

 

 Because lots of good data has this format, we'll start by writing a

 template function to extract it:

 

 #+name: hxc-thunks

 #+begin_src clojure :results silent

 (defn hxc-thunk

   "Creates a thunk (nullary fn) that grabs data in a certain region of rom and

 splits it into a collection by 0x50. If rom is not supplied, uses the

   original rom data."

   [start length]

   (fn self

     ([rom]

        (take-nth 2

                  (partition-by #(= % 0x50)

                                (take length

                                      (drop start rom)))))

     ([]

       (self com.aurellem.gb.gb-driver/original-rom))))

 

 (def hxc-thunk-words

   "Same as hxc-thunk, except it interprets the rom data as characters,

   returning a collection of strings."

   (comp

    (partial comp (partial map character-codes->str))

    hxc-thunk))

 

 #+end_src

 

 

 * Pok\eacute{}mon I

 ** Names of each species

 The names of the Pok\eacute{}mon species are stored in

 ROM@E8000. This name list is interesting, for a number of reasons:

 - The names are stored in [[ ][internal order]] rather than in the familiar

   Pok\eacute{}dex order. This seemingly random order probably represents the order in which the authors created or

   programmed in the Pok\eacute{}mon; it's used throughout the game.

 - There is enough space allocated for 190 Pok\eacute{}mon. As I

   understand it, there were originally going to be 190 Pok\eacute{}mon

   in Generation I, but the creators decided to defer some to

   Generation II. This explains why many Gen I and Gen II Pok\eacute{}mon

   have the same aesthetic feel.

 - The list is pockmarked with random gaps, due to the strange internal

   ordering

   and the 39 unused spaces [fn::190 allocated spaces minus 151 true Pok\eacute{}mon]. These missing spaces are filled with the

   placeholder name  =MISSINGNO.= (\ldquo{}Missing number\rdquo{}).

 

 Each name is exactly ten letters long; whenever a name would be too short, the extra

 space is padded with the character 0x50. 

 

 *** See the data

 

 Here you can see the raw data in three stages: in the first stage, we

 just grab the first few bytes starting from position 0xE8000. In the

 second stage, we partition the bytes into ten-letter chunks to show you

 where the names begin and end. In the final stage, we convert each

 byte into the letter it represents using the =character-codes->str=

 function. (0x50 is rendered as the symbol \ldquo{} =#= \rdquo{} for

 ease of reading).

 

 #+begin_src clojure :exports both :cache no :results output 

 (ns com.aurellem.gb.hxc

   (:use (com.aurellem.gb assembly characters gb-driver util mem-util

                          constants))

   (:import [com.aurellem.gb.gb_driver SaveState]))

 

 

 (println (take 100 (drop 0xE8000 (rom))))

 

 (println (partition 10 (take 100 (drop 0xE8000 (rom)))))

 

 (println (character-codes->str (take 100 (drop 0xE8000 (rom)))))

 

 

 #+end_src

 

 #+results:

 : (145 135 152 131 142 141 80 80 80 80 138 128 141 134 128 146 138 135 128 141 141 136 131 142 145 128 141 239 80 80 130 139 132 133 128 136 145 152 80 80 146 143 132 128 145 142 150 80 80 80 149 142 139 147 142 145 129 80 80 80 141 136 131 142 138 136 141 134 80 80 146 139 142 150 129 145 142 80 80 80 136 149 152 146 128 148 145 80 80 80 132 151 132 134 134 148 147 142 145 80)

 : ((145 135 152 131 142 141 80 80 80 80) (138 128 141 134 128 146 138 135 128 141) (141 136 131 142 145 128 141 239 80 80) (130 139 132 133 128 136 145 152 80 80) (146 143 132 128 145 142 150 80 80 80) (149 142 139 147 142 145 129 80 80 80) (141 136 131 142 138 136 141 134 80 80) (146 139 142 150 129 145 142 80 80 80) (136 149 152 146 128 148 145 80 80 80) (132 151 132 134 134 148 147 142 145 80))

 : RHYDON####KANGASKHANNIDORAN♂##CLEFAIRY##SPEAROW###VOLTORB###NIDOKING##SLOWBRO###IVYSAUR###EXEGGUTOR#

 

 

 *** Automatically grab the data.

 

     #+name: pokenames

     #+begin_src clojure

 

 (defn hxc-pokenames-raw

   "The hardcoded names of the 190 species in memory. List begins at

 ROM@E8000. Although names in memory are padded with 0x50 to be 10 characters

   long, these names are stripped of padding. See also, hxc-pokedex-names"

   ([]

      (hxc-pokenames-raw com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [count-species 190

            name-length 10]

        (map character-codes->str

             (partition name-length

                        (map #(if (= 0x50 %) 0x00 %)

                             (take (* count-species name-length)

                                   (drop 0xE8000

                                         rom))))))))

 (def hxc-pokenames

   (comp

    (partial map format-name)

    hxc-pokenames-raw))

 

 

 

 

 (defn hxc-pokedex-names

   "The names of the pokemon in hardcoded pokedex order. List begins at

 ROM@410B1. See also, hxc-pokenames."

   ([] (hxc-pokedex-names

        com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [names (hxc-pokenames rom)]

        (#(mapv %

                ((comp range count keys) %))

         (zipmap

          (take (count names)

                (drop 0x410b1 rom))

          

          names)))))

 

     #+end_src

 

 

 

 ** Generic species information

 

 #+name: pokebase

 #+begin_src clojure

 (defn hxc-pokemon-base

   ([] (hxc-pokemon-base com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [entry-size 28

           

            pokemon (rest (hxc-pokedex-names))

  pkmn-count (inc(count pokemon))

            types (apply assoc {}

                         (interleave

                          (range)

                          pkmn-types)) ;;!! softcoded

            moves (apply assoc {}

                         (interleave

                          (range)

                          (map format-name

                               (hxc-move-names rom))))

            machines (hxc-machines)

            ]

        (zipmap

         pokemon

         (map

          (fn [[n

                rating-hp

                rating-atk

                rating-def

                rating-speed

                rating-special

                type-1

                type-2

                rarity

                rating-xp

                pic-dimensions ;; tile_width|tile_height (8px/tile)

                ptr-pic-obverse-1

                ptr-pic-obverse-2

                ptr-pic-reverse-1

                ptr-pic-reverse-2

                move-1

                move-2

                move-3

                move-4

                growth-rate

                &

                TMs|HMs]]

            (let

                [base-moves

                 (mapv moves

                       ((comp

                         ;; since the game uses zero as a delimiter,

                         ;; it must also increment all move indices by 1.

                         ;; heren we decrement to correct this.

                         (partial map dec)

                         (partial take-while (comp not zero?)))

                        [move-1 move-2 move-3 move-4]))

                 

                 types

                 (set (list (types type-1)

                            (types type-2)))

                 TMs|HMs

                 (map

                  (comp

                   (partial map first)

                   (partial remove (comp zero? second)))

                  (split-at

                   50

                   (map vector

                        (rest(range))

                        (reduce concat

                                (map

                                 #(take 8

                                        (concat (bit-list %)

                                                (repeat 0)))

                                 

                                 TMs|HMs)))))

                 

                 TMs  (vec (first TMs|HMs))

                 HMs (take 5 (map (partial + -50) (vec (second TMs|HMs))))

                 

                 

                 ]

              

              

              {:dex# n

               :base-moves base-moves

               :types types

               :TMs TMs

               :HMs HMs

               :base-hp rating-hp

               :base-atk rating-atk

               :base-def rating-def

               :base-speed rating-speed

               :base-special rating-special

               :o0 pic-dimensions

               :o1 ptr-pic-obverse-1

               :o2 ptr-pic-obverse-2

               }))

          

          (partition entry-size

                     (take (* entry-size pkmn-count)

                           (drop 0x383DE

                                 rom))))))))

 

 #+end_src

 

 

 ** Pok\eacute{}mon evolutions

 #+name: evolution-header

 #+begin_src clojure

 (defn format-evo

   "Parse a sequence of evolution data, returning a map. First is the

 method: 0 = end-evolution-data. 1 = level-up, 2 = item, 3 = trade. Next is an item id, if the

   method of evolution is by item (only stones will actually make pokemon

   evolve, for some auxillary reason.) Finally, the minimum level for

   evolution to occur (level 1 means no limit, which is used for trade

   and item evolutions), followed by the internal id of the pokemon

   into which to evolve. Hence, level up and trade evolutions are

   described with 3

   bytes; item evolutions with four."

   [coll]

   (let [method (first coll)]

     (cond (empty? coll) []

           (= 0 method) [] ;; just in case

           (= 1 method) ;; level-up evolution

           (conj (format-evo (drop 3 coll))

                             {:method :level-up

                              :min-level (nth coll 1)

                              :into (dec (nth coll 2))})

           

           (= 2 method) ;; item evolution

           (conj (format-evo (drop 4 coll))

                 {:method :item

                  :item (dec (nth coll 1))

                  :min-level (nth coll 2)

                  :into (dec (nth coll 3))})

 

           (= 3 method) ;; trade evolution

           (conj (format-evo (drop 3 coll))

                 {:method :trade

                  :min-level (nth coll 1) ;; always 1 for trade.

                  :into (dec (nth coll 2))}))))

 

 

 (defn hxc-ptrs-evolve

   "A hardcoded collection of 190 pointers to alternating evolution/learnset data,

 in internal order."

   ([]

      (hxc-ptrs-evolve com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [

            pkmn-count (count (hxc-pokenames-raw)) ;; 190

            ptrs

            (map (fn [[a b]] (low-high a b))

                 (partition 2

                            (take (* 2 pkmn-count)

                                  (drop 0x3b1e5 rom))))]

        (map (partial + 0x34000) ptrs)

 

        )))

 #+end_src

 

 #+name:evolution

 #+begin_src clojure

 

 (defn hxc-evolution

   "Hardcoded evolution data in memory. The data exists at ROM@34000,

   sorted by internal order. Pointers to the data exist at ROM@3B1E5; see also, hxc-ptrs-evolve."

   ([] (hxc-evolution com.aurellem.gb.gb-driver/original-rom))

   ([rom]

        (apply assoc {}

                (interleave

                 (hxc-pokenames rom)

                 (map

                  (comp

                   format-evo

                   (partial take-while (comp not zero?))

                   #(drop % rom))

                  (hxc-ptrs-evolve rom)

                  )))))

 

 (defn hxc-evolution-pretty

   "Like hxc-evolution, except it uses the names of items and pokemon

 --- grabbed from ROM --- rather than their numerical identifiers."

   ([] (hxc-evolution-pretty com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let

          [poke-names (vec (hxc-pokenames rom))

           item-names (vec (hxc-items rom))

           use-names

           (fn [m]

             (loop [ks (keys m) new-map m]

               (let [k (first ks)]

                 (cond (nil? ks) new-map

                       (= k :into)

                       (recur

                        (next ks)

                        (assoc new-map

                          :into

                          (poke-names

                           (:into

                            new-map))))

                       (= k :item)

                       (recur

                        (next ks)

                        (assoc new-map

                          :item

                          (item-names

                           (:item new-map))))

                       :else

                       (recur

                        (next ks)

                        new-map)

                       ))))]

 

        (into {}

              (map (fn [[pkmn evo-coll]]

                     [pkmn (map use-names evo-coll)])

                   (hxc-evolution rom))))))

 

 

 #+end_src

 

 

 ** Level-up moves (learnsets)

 #+name: learnsets

 #+begin_src clojure

 

 

 (defn hxc-learnsets

   "Hardcoded map associating pokemon names to lists of pairs [lvl

   move] of abilities they learn as they level up. The data

 exists at ROM@34000, sorted by internal order. Pointers to the data

   exist at ROM@3B1E5; see also, hxc-ptrs-evolve"

   ([] (hxc-learnsets com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (apply assoc

             {}

             (interleave

              (hxc-pokenames rom)

              (map (comp

                    (partial map

                             (fn [[lvl mv]] [lvl (dec mv)]))

                    (partial partition 2)

                    ;; keep the learnset data

                    (partial take-while (comp not zero?))

                    ;; skip the evolution data

                    rest

                    (partial drop-while (comp not zero?)))

                   (map #(drop % rom) 

                        (hxc-ptrs-evolve rom)))))))

 

 (defn hxc-learnsets-pretty

   "Live hxc-learnsets except it reports the name of each move --- as

 it appears in rom --- rather than the move index."

   ([] (hxc-learnsets-pretty com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [moves (vec(map format-name (hxc-move-names)))]

        (into {}

              (map (fn [[pkmn learnset]]

                     [pkmn (map (fn [[lvl mv]] [lvl (moves mv)])

                                learnset)])

                   (hxc-learnsets rom))))))

              

                                   

 

 #+end_src

 

 

 

 * Pok\eacute{}mon II : the Pok\eacute{}dex

 ** Species vital stats

 #+name: dex-stats

 #+begin_src clojure

 (defn hxc-pokedex-stats

   "The hardcoded pokedex stats (species height weight) in memory. List

 begins at ROM@40687"

   ([] (hxc-pokedex-stats com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [pokedex-names (zipmap (range) (hxc-pokedex-names rom))

            pkmn-count (count pokedex-names)

            ]

      ((fn capture-stats

         [n stats data]

         (if (zero? n) stats

             (let [[species

                    [_

                     height-ft

                     height-in

                     weight-1

                     weight-2

                     _

                     dex-ptr-1

                     dex-ptr-2

                     dex-bank

                     _

                     & data]]

                   (split-with (partial not= 0x50) data)]

               (recur (dec n)

                      (assoc stats

                        (pokedex-names (- pkmn-count (dec n)))

                        {:species

                         (format-name (character-codes->str species))

                         :height-ft

                         height-ft

                         :height-in

                         height-in

                         :weight

                         (/ (low-high weight-1 weight-2) 10.)

                         

                     ;;    :text

                     ;;    (character-codes->str

                     ;;     (take-while

                     ;;      (partial not= 0x50)

                     ;;      (drop

                     ;;       (+ 0xB8000

                     ;;          -0x4000

                     ;;          (low-high dex-ptr-1 dex-ptr-2))

                     ;;       rom)))

                         })

                      

                      data)

               

               

               )))

       

       pkmn-count

       {}

       (drop 0x40687 rom)))       ))

 #+end_src

 

 ** Species synopses

 

 #+name: dex-text

 #+begin_src clojure

 (def hxc-pokedex-text-raw

   "The hardcoded pokedex entries in memory. List begins at

 ROM@B8000, shortly before move names."

   (hxc-thunk-words 0xB8000 14754))

 

 

 

 

 (defn hxc-pokedex-text

   "The hardcoded pokedex entries in memory, presented as an

 associative hash map. List begins at ROM@B8000."

   ([] (hxc-pokedex-text com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (zipmap

       (hxc-pokedex-names rom)

       (cons nil ;; for missingno.

             (hxc-pokedex-text-raw rom)))))

 #+end_src

 

 

 ** Pok\eacute{}mon cries

 #+name: pokecry

 #+begin_src clojure

 (defn hxc-cry

   "The pokemon cry data in internal order. List begins at ROM@39462"

   ([](hxc-cry com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (zipmap

       (hxc-pokenames rom)

       (map

        (fn [[cry-id pitch length]]

          {:cry-id cry-id

          :pitch pitch

           :length length}

          )

        (partition 3

                   (drop 0x39462 rom))))))

 

 (defn hxc-cry-groups

   ([] (hxc-cry-groups com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (map #(mapv first

                 (filter

                  (fn [[k v]]

                    (= % (:cry-id v)))

                  (hxc-cry)))

           ((comp

             range

             count

             set

             (partial map :cry-id)

             vals

             hxc-cry)

            rom))))

 

 

 (defn cry-conversion!

   "Convert Porygon's cry in ROM to be the cry of the given pokemon."

   [pkmn]

   (write-rom!

    (rewrite-memory

     (vec(rom))

     0x3965D 

     (map second

          ((hxc-cry) pkmn)))))

 

 #+end_src

 

 ** COMMENT Names of permanent stats

 0DD4D-DD72   

 

 * Items

 ** Item names

 

 *** See the data

 #+begin_src clojure :exports both :results output 

 (ns com.aurellem.gb.hxc

   (:use (com.aurellem.gb assembly characters gb-driver util mem-util

                          constants))

   (:import [com.aurellem.gb.gb_driver SaveState]))

 

 (println (take 100 (drop 0x045B7 (rom))))

 

 (println

  (partition-by

   (partial = 0x50)

   (take 100 (drop 0x045B7 (rom)))))

 

 (println

  (map character-codes->str

       (partition-by

        (partial = 0x50)

        (take 100 (drop 0x045B7 (rom))))))

 

 

 #+end_src

 

 #+results:

 : (140 128 146 147 132 145 127 129 128 139 139 80 148 139 147 145 128 127 129 128 139 139 80 134 145 132 128 147 127 129 128 139 139 80 143 142 138 186 127 129 128 139 139 80 147 142 150 141 127 140 128 143 80 129 136 130 152 130 139 132 80 230 230 230 230 230 80 146 128 133 128 145 136 127 129 128 139 139 80 143 142 138 186 131 132 151 80 140 142 142 141 127 146 147 142 141 132 80 128 141)

 : ((140 128 146 147 132 145 127 129 128 139 139) (80) (148 139 147 145 128 127 129 128 139 139) (80) (134 145 132 128 147 127 129 128 139 139) (80) (143 142 138 186 127 129 128 139 139) (80) (147 142 150 141 127 140 128 143) (80) (129 136 130 152 130 139 132) (80) (230 230 230 230 230) (80) (146 128 133 128 145 136 127 129 128 139 139) (80) (143 142 138 186 131 132 151) (80) (140 142 142 141 127 146 147 142 141 132) (80) (128 141))

 : (MASTER BALL # ULTRA BALL # GREAT BALL # POKé BALL # TOWN MAP # BICYCLE # ????? # SAFARI BALL # POKéDEX # MOON STONE # AN)

 

 *** Automatically grab the data

 #+name: item-names

 #+begin_src clojure

 

 (def hxc-items-raw

   "The hardcoded names of the items in memory. List begins at

 ROM@045B7"

   (hxc-thunk-words 0x45B7 870))

 

 (def hxc-items

   "The hardcoded names of the items in memory, presented as

   keywords. List begins at ROM@045B7. See also, hxc-items-raw."

   (comp (partial map format-name) hxc-items-raw))

 #+end_src

 

 ** Item prices

 

 ***

 #+begin_src clojure :exports both :results output 

 (ns com.aurellem.gb.hxc

   (:use (com.aurellem.gb assembly characters gb-driver util mem-util

                          constants))

   (:import [com.aurellem.gb.gb_driver SaveState]))

 

 (println (take 90 (drop 0x4495 (rom))))

 

 (println

  (partition 3

             (take 90 (drop 0x4495 (rom)))))

 

 (println

  (partition 3

             (map hex

                  (take 90 (drop 0x4495 (rom))))))

 

 (println

  (map decode-bcd

       (map butlast

            (partition 3

                       (take 90 (drop 0x4495 (rom)))))))

 

 (println

  (map

   vector

   (hxc-items (rom))

   (map decode-bcd

        (map butlast

             (partition 3

                        (take 90 (drop 0x4495 (rom))))))))

  

 

 

 

 

 #+end_src

 

 #+results:

 : (0 0 0 18 0 0 6 0 0 2 0 0 0 0 0 0 0 0 0 0 0 16 0 0 0 0 0 0 0 0 1 0 0 2 80 0 2 80 0 2 0 0 2 0 0 48 0 0 37 0 0 21 0 0 7 0 0 3 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 5 80 0 3 80 0)

 : ((0 0 0) (18 0 0) (6 0 0) (2 0 0) (0 0 0) (0 0 0) (0 0 0) (16 0 0) (0 0 0) (0 0 0) (1 0 0) (2 80 0) (2 80 0) (2 0 0) (2 0 0) (48 0 0) (37 0 0) (21 0 0) (7 0 0) (3 0 0) (0 0 0) (0 0 0) (0 0 0) (0 0 0) (0 0 0) (0 0 0) (0 0 0) (0 0 0) (5 80 0) (3 80 0))

 : ((0x0 0x0 0x0) (0x12 0x0 0x0) (0x6 0x0 0x0) (0x2 0x0 0x0) (0x0 0x0 0x0) (0x0 0x0 0x0) (0x0 0x0 0x0) (0x10 0x0 0x0) (0x0 0x0 0x0) (0x0 0x0 0x0) (0x1 0x0 0x0) (0x2 0x50 0x0) (0x2 0x50 0x0) (0x2 0x0 0x0) (0x2 0x0 0x0) (0x30 0x0 0x0) (0x25 0x0 0x0) (0x15 0x0 0x0) (0x7 0x0 0x0) (0x3 0x0 0x0) (0x0 0x0 0x0) (0x0 0x0 0x0) (0x0 0x0 0x0) (0x0 0x0 0x0) (0x0 0x0 0x0) (0x0 0x0 0x0) (0x0 0x0 0x0) (0x0 0x0 0x0) (0x5 0x50 0x0) (0x3 0x50 0x0))

 : (0 1200 600 200 0 0 0 1000 0 0 100 250 250 200 200 3000 2500 1500 700 300 0 0 0 0 0 0 0 0 550 350)

 : ([:master-ball 0] [:ultra-ball 1200] [:great-ball 600] [:poké-ball 200] [:town-map 0] [:bicycle 0] [:????? 0] [:safari-ball 1000] [:pokédex 0] [:moon-stone 0] [:antidote 100] [:burn-heal 250] [:ice-heal 250] [:awakening 200] [:parlyz-heal 200] [:full-restore 3000] [:max-potion 2500] [:hyper-potion 1500] [:super-potion 700] [:potion 300] [:boulderbadge 0] [:cascadebadge 0] [:thunderbadge 0] [:rainbowbadge 0] [:soulbadge 0] [:marshbadge 0] [:volcanobadge 0] [:earthbadge 0] [:escape-rope 550] [:repel 350])

 

 

 ***

 #+name: item-prices

 #+begin_src clojure

 (defn hxc-item-prices

   "The hardcoded list of item prices in memory. List begins at ROM@4495"

   ([] (hxc-item-prices com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [items (hxc-items rom)

            price-size 3]

        (zipmap items

                (map (comp

                      ;; zero-cost items are "priceless"

                      #(if (zero? %) :priceless %)

                      decode-bcd butlast)

                     (partition price-size

                                (take (* price-size (count items))

                                      (drop 0x4495 rom))))))))

 #+end_src

 ** Vendor inventories

 

 #+name: item-vendors

 #+begin_src clojure

 (defn hxc-shops

   ([] (hxc-shops com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [items (zipmap (range) (hxc-items rom))

 

            ;; temporarily softcode the TM items

            items (into

                   items

                   (map (juxt identity

                              (comp keyword

                                    (partial str "tm-")

                                    (partial + 1 -200)

                                    )) 

                        (take 200 (drop 200 (range)))))

                        

            ]

 

        ((fn parse-shop [coll [num-items & items-etc]]

           (let [inventory (take-while

                            (partial not= 0xFF)

                            items-etc)

                [separator & items-etc] (drop num-items (rest items-etc))]

            (if (= separator 0x50)

              (map (partial mapv (comp items dec)) (conj coll inventory))

              (recur (conj coll inventory) items-etc)

              )

          ))

 

         '()

         (drop 0x233C rom))

 

      

      )))

 #+end_src

 

 #+results: item-vendors

 : #'com.aurellem.gb.hxc/hxc-shops

 

 

 

 * Types

 ** Names of types

 

 *** COMMENT Pointers to type names

 #+begin_src clojure :exports both :results output

 (map (comp character-codes->str #(take-while (partial not= 80) (drop % (rom))) (partial + 0x20000) (partial apply low-high)) (partition 2 (take 54 (drop 0x27D63 (rom)))))

 #+end_src

 

 

 ***

 #+begin_src clojure :exports both :results output 

 (ns com.aurellem.gb.hxc

   (:use (com.aurellem.gb assembly characters gb-driver util mem-util

                          constants))

   (:import [com.aurellem.gb.gb_driver SaveState]))

 

 (println (take 90 (drop 0x27D99 (rom))))

 

 (println

  (partition-by (partial = 0x50)

                (take 90 (drop 0x27D99 (rom)))))

 

 (println

  (map character-codes->str

       (partition-by (partial = 0x50)

                     (take 90 (drop 0x27D99 (rom))))))

 

 #+end_src

 

 #+results:

 : (141 142 145 140 128 139 80 133 136 134 135 147 136 141 134 80 133 139 152 136 141 134 80 143 142 136 146 142 141 80 133 136 145 132 80 150 128 147 132 145 80 134 145 128 146 146 80 132 139 132 130 147 145 136 130 80 143 146 152 130 135 136 130 80 136 130 132 80 134 145 142 148 141 131 80 145 142 130 138 80 129 136 145 131 80 129 148 134 80 134)

 : ((141 142 145 140 128 139) (80) (133 136 134 135 147 136 141 134) (80) (133 139 152 136 141 134) (80) (143 142 136 146 142 141) (80) (133 136 145 132) (80) (150 128 147 132 145) (80) (134 145 128 146 146) (80) (132 139 132 130 147 145 136 130) (80) (143 146 152 130 135 136 130) (80) (136 130 132) (80) (134 145 142 148 141 131) (80) (145 142 130 138) (80) (129 136 145 131) (80) (129 148 134) (80) (134))

 : (NORMAL # FIGHTING # FLYING # POISON # FIRE # WATER # GRASS # ELECTRIC # PSYCHIC # ICE # GROUND # ROCK # BIRD # BUG # G)

 

 

 ***

 #+name: type-names

 #+begin_src clojure

 (def hxc-types

   "The hardcoded type names in memory. List begins at ROM@27D99,

   shortly before hxc-titles."

   (hxc-thunk-words 0x27D99 102))

 

 #+end_src

 

 ** Type effectiveness

 ***

 #+begin_src clojure :exports both :results output 

 (ns com.aurellem.gb.hxc

   (:use (com.aurellem.gb assembly characters gb-driver util mem-util

                          constants))

   (:import [com.aurellem.gb.gb_driver SaveState]))

 

 

 ;; POKEMON TYPES

 

 (println pkmn-types) ;; these are the pokemon types

 (println (map vector (range) pkmn-types)) ;; each type has an id number.

 

 (newline)

 

 

 

 

 ;;; TYPE EFFECTIVENESS

 

 (println (take 15 (drop 0x3E62D (rom))))

 (println (partition 3 (take 15 (drop 0x3E62D (rom)))))

 

 (println

  (map

   (fn [[atk-type def-type multiplier]]

     (list atk-type def-type (/ multiplier 10.)))

 

   (partition 3

              (take 15 (drop 0x3E62D (rom))))))

 

 

 (println

  (map

   (fn [[atk-type def-type multiplier]]

     [

      (get pkmn-types atk-type)

      (get pkmn-types def-type)

      (/ multiplier 10.)

     ])

   

   (partition 3

              (take 15 (drop 0x3E62D (rom))))))

 

 #+end_src

 

 #+results:

 : [:normal :fighting :flying :poison :ground :rock :bird :bug :ghost :A :B :C :D :E :F :G :H :I :J :K :fire :water :grass :electric :psychic :ice :dragon]

 : ([0 :normal] [1 :fighting] [2 :flying] [3 :poison] [4 :ground] [5 :rock] [6 :bird] [7 :bug] [8 :ghost] [9 :A] [10 :B] [11 :C] [12 :D] [13 :E] [14 :F] [15 :G] [16 :H] [17 :I] [18 :J] [19 :K] [20 :fire] [21 :water] [22 :grass] [23 :electric] [24 :psychic] [25 :ice] [26 :dragon])

 : 

 : (0 5 5 0 8 0 8 8 20 20 7 20 20 5 5)

 : ((0 5 5) (0 8 0) (8 8 20) (20 7 20) (20 5 5))

 : ((0 5 0.5) (0 8 0.0) (8 8 2.0) (20 7 2.0) (20 5 0.5))

 : ([:normal :rock 0.5] [:normal :ghost 0.0] [:ghost :ghost 2.0] [:fire :bug 2.0] [:fire :rock 0.5])

 

 

 ***

 

 #+name: type-advantage

 #+begin_src clojure

 (defn hxc-advantage

   ;; in-game multipliers are stored as 10x their effective value

   ;; to allow for fractional multipliers like 1/2

   

   "The hardcoded type advantages in memory, returned as tuples of

   atk-type def-type multiplier. By default (i.e. if not listed here),

 the multiplier is 1. List begins at 0x3E62D."

   ([] (hxc-advantage com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (map

       (fn [[atk def mult]] [(get pkmn-types atk (hex atk))

                             (get pkmn-types def (hex def))

                             (/ mult 10)])

       (partition 3

                  (take-while (partial not= 0xFF)

                              (drop 0x3E62D rom))))))

 #+end_src

 

 

 

 * Moves

 ** Names of moves

 *** See the data

 #+begin_src clojure :exports both :results output 

 (ns com.aurellem.gb.hxc

   (:use (com.aurellem.gb assembly characters gb-driver util mem-util

                          constants))

   (:import [com.aurellem.gb.gb_driver SaveState]))

 

 (println (take 100 (drop 0xBC000 (rom))))

 

 (println

  (partition-by

   (partial = 0x50)

   (take 100 (drop 0xBC000 (rom)))))

 

 (println

  (map character-codes->str

       (partition-by

        (partial = 0x50)

        (take 100 (drop 0xBC000 (rom))))))

 

 

 #+end_src

 

 #+results:

 : (143 142 148 141 131 80 138 128 145 128 147 132 127 130 135 142 143 80 131 142 148 129 139 132 146 139 128 143 80 130 142 140 132 147 127 143 148 141 130 135 80 140 132 134 128 127 143 148 141 130 135 80 143 128 152 127 131 128 152 80 133 136 145 132 127 143 148 141 130 135 80 136 130 132 127 143 148 141 130 135 80 147 135 148 141 131 132 145 143 148 141 130 135 80 146 130 145 128 147 130)

 : ((143 142 148 141 131) (80) (138 128 145 128 147 132 127 130 135 142 143) (80) (131 142 148 129 139 132 146 139 128 143) (80) (130 142 140 132 147 127 143 148 141 130 135) (80) (140 132 134 128 127 143 148 141 130 135) (80) (143 128 152 127 131 128 152) (80) (133 136 145 132 127 143 148 141 130 135) (80) (136 130 132 127 143 148 141 130 135) (80) (147 135 148 141 131 132 145 143 148 141 130 135) (80) (146 130 145 128 147 130))

 : (POUND # KARATE CHOP # DOUBLESLAP # COMET PUNCH # MEGA PUNCH # PAY DAY # FIRE PUNCH # ICE PUNCH # THUNDERPUNCH # SCRATC)

 

 *** Automatically grab the data

 

 #+name: move-names

 #+begin_src clojure

 (def hxc-move-names

   "The hardcoded move names in memory. List begins at ROM@BC000"

   (hxc-thunk-words 0xBC000 1551))

 #+end_src

    

 ** Properties of moves 

 

 #+name: move-data

 #+begin_src clojure

 (defn hxc-move-data

   "The hardcoded (basic (move effects)) in memory. List begins at

 0x38000. Returns a map of {:name :power :accuracy :pp :fx-id

   :fx-txt}. The move descriptions are handwritten, not hardcoded."

   ([]

      (hxc-move-data com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [names (vec (hxc-move-names rom))

            move-count (count names)

            move-size 6

            types pkmn-types ;;; !! hardcoded types

            ]

        (zipmap (map format-name names)

                (map

                 (fn [[idx effect power type-id accuracy pp]]

                   {:name (names (dec idx))

                    :power power

                    :accuracy  accuracy

                    :pp pp

                    :type (types type-id)

                    :fx-id effect

                    :fx-txt (get move-effects effect) 

                    }

                   )

                 

                 (partition move-size

                            (take (* move-size move-count)

                                  (drop 0x38000 rom))))))))

   

 

 

 (defn hxc-move-data*

   "Like hxc-move-data, but reports numbers as hexadecimal symbols instead."

   ([]

      (hxc-move-data* com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [names (vec (hxc-move-names rom))

            move-count (count names)

            move-size 6

            format-name (fn [s]

                          (keyword (.toLowerCase

                                    (apply str

                                           (map #(if (= % \space) "-" %) s)))))

            ]

        (zipmap (map format-name names)

                (map

                 (fn [[idx effect power type accuracy pp]]

                   {:name (names (dec idx))

                    :power power

                    :accuracy (hex accuracy)

                    :pp pp

                    :fx-id (hex effect)

                    :fx-txt (get move-effects effect) 

                    }

                   )

                 

                 (partition move-size

                            (take (* move-size move-count)

                                  (drop 0x38000 rom))))))))

   

 #+end_src

 

 ** TM and HM moves

 ***

 #+begin_src clojure :exports both :results output 

 (ns com.aurellem.gb.hxc

   (:use (com.aurellem.gb assembly characters gb-driver util mem-util

                          constants))

   (:import [com.aurellem.gb.gb_driver SaveState]))

 

 

 (println (hxc-move-names))

 (println (map vector (rest(range)) (hxc-move-names)))

 

 (newline)

 

 (println (take 55 (drop 0x1232D (rom))))

 

 (println

  (interpose "."

             (map

              (zipmap (rest (range)) (hxc-move-names))

              (take 55 (drop 0x1232D (rom))))))

 

 #+end_src

 

 #+results:

 : (POUND KARATE CHOP DOUBLESLAP COMET PUNCH MEGA PUNCH PAY DAY FIRE PUNCH ICE PUNCH THUNDERPUNCH SCRATCH VICEGRIP GUILLOTINE RAZOR WIND SWORDS DANCE CUT GUST WING ATTACK WHIRLWIND FLY BIND SLAM VINE WHIP STOMP DOUBLE KICK MEGA KICK JUMP KICK ROLLING KICK SAND-ATTACK HEADBUTT HORN ATTACK FURY ATTACK HORN DRILL TACKLE BODY SLAM WRAP TAKE DOWN THRASH DOUBLE-EDGE TAIL WHIP POISON STING TWINEEDLE PIN MISSILE LEER BITE GROWL ROAR SING SUPERSONIC SONICBOOM DISABLE ACID EMBER FLAMETHROWER MIST WATER GUN HYDRO PUMP SURF ICE BEAM BLIZZARD PSYBEAM BUBBLEBEAM AURORA BEAM HYPER BEAM PECK DRILL PECK SUBMISSION LOW KICK COUNTER SEISMIC TOSS STRENGTH ABSORB MEGA DRAIN LEECH SEED GROWTH RAZOR LEAF SOLARBEAM POISONPOWDER STUN SPORE SLEEP POWDER PETAL DANCE STRING SHOT DRAGON RAGE FIRE SPIN THUNDERSHOCK THUNDERBOLT THUNDER WAVE THUNDER ROCK THROW EARTHQUAKE FISSURE DIG TOXIC CONFUSION PSYCHIC HYPNOSIS MEDITATE AGILITY QUICK ATTACK RAGE TELEPORT NIGHT SHADE MIMIC SCREECH DOUBLE TEAM RECOVER HARDEN MINIMIZE SMOKESCREEN CONFUSE RAY WITHDRAW DEFENSE CURL BARRIER LIGHT SCREEN HAZE REFLECT FOCUS ENERGY BIDE METRONOME MIRROR MOVE SELFDESTRUCT EGG BOMB LICK SMOG SLUDGE BONE CLUB FIRE BLAST WATERFALL CLAMP SWIFT SKULL BASH SPIKE CANNON CONSTRICT AMNESIA KINESIS SOFTBOILED HI JUMP KICK GLARE DREAM EATER POISON GAS BARRAGE LEECH LIFE LOVELY KISS SKY ATTACK TRANSFORM BUBBLE DIZZY PUNCH SPORE FLASH PSYWAVE SPLASH ACID ARMOR CRABHAMMER EXPLOSION FURY SWIPES BONEMERANG REST ROCK SLIDE HYPER FANG SHARPEN CONVERSION TRI ATTACK SUPER FANG SLASH SUBSTITUTE STRUGGLE)

 : ([1 POUND] [2 KARATE CHOP] [3 DOUBLESLAP] [4 COMET PUNCH] [5 MEGA PUNCH] [6 PAY DAY] [7 FIRE PUNCH] [8 ICE PUNCH] [9 THUNDERPUNCH] [10 SCRATCH] [11 VICEGRIP] [12 GUILLOTINE] [13 RAZOR WIND] [14 SWORDS DANCE] [15 CUT] [16 GUST] [17 WING ATTACK] [18 WHIRLWIND] [19 FLY] [20 BIND] [21 SLAM] [22 VINE WHIP] [23 STOMP] [24 DOUBLE KICK] [25 MEGA KICK] [26 JUMP KICK] [27 ROLLING KICK] [28 SAND-ATTACK] [29 HEADBUTT] [30 HORN ATTACK] [31 FURY ATTACK] [32 HORN DRILL] [33 TACKLE] [34 BODY SLAM] [35 WRAP] [36 TAKE DOWN] [37 THRASH] [38 DOUBLE-EDGE] [39 TAIL WHIP] [40 POISON STING] [41 TWINEEDLE] [42 PIN MISSILE] [43 LEER] [44 BITE] [45 GROWL] [46 ROAR] [47 SING] [48 SUPERSONIC] [49 SONICBOOM] [50 DISABLE] [51 ACID] [52 EMBER] [53 FLAMETHROWER] [54 MIST] [55 WATER GUN] [56 HYDRO PUMP] [57 SURF] [58 ICE BEAM] [59 BLIZZARD] [60 PSYBEAM] [61 BUBBLEBEAM] [62 AURORA BEAM] [63 HYPER BEAM] [64 PECK] [65 DRILL PECK] [66 SUBMISSION] [67 LOW KICK] [68 COUNTER] [69 SEISMIC TOSS] [70 STRENGTH] [71 ABSORB] [72 MEGA DRAIN] [73 LEECH SEED] [74 GROWTH] [75 RAZOR LEAF] [76 SOLARBEAM] [77 POISONPOWDER] [78 STUN SPORE] [79 SLEEP POWDER] [80 PETAL DANCE] [81 STRING SHOT] [82 DRAGON RAGE] [83 FIRE SPIN] [84 THUNDERSHOCK] [85 THUNDERBOLT] [86 THUNDER WAVE] [87 THUNDER] [88 ROCK THROW] [89 EARTHQUAKE] [90 FISSURE] [91 DIG] [92 TOXIC] [93 CONFUSION] [94 PSYCHIC] [95 HYPNOSIS] [96 MEDITATE] [97 AGILITY] [98 QUICK ATTACK] [99 RAGE] [100 TELEPORT] [101 NIGHT SHADE] [102 MIMIC] [103 SCREECH] [104 DOUBLE TEAM] [105 RECOVER] [106 HARDEN] [107 MINIMIZE] [108 SMOKESCREEN] [109 CONFUSE RAY] [110 WITHDRAW] [111 DEFENSE CURL] [112 BARRIER] [113 LIGHT SCREEN] [114 HAZE] [115 REFLECT] [116 FOCUS ENERGY] [117 BIDE] [118 METRONOME] [119 MIRROR MOVE] [120 SELFDESTRUCT] [121 EGG BOMB] [122 LICK] [123 SMOG] [124 SLUDGE] [125 BONE CLUB] [126 FIRE BLAST] [127 WATERFALL] [128 CLAMP] [129 SWIFT] [130 SKULL BASH] [131 SPIKE CANNON] [132 CONSTRICT] [133 AMNESIA] [134 KINESIS] [135 SOFTBOILED] [136 HI JUMP KICK] [137 GLARE] [138 DREAM EATER] [139 POISON GAS] [140 BARRAGE] [141 LEECH LIFE] [142 LOVELY KISS] [143 SKY ATTACK] [144 TRANSFORM] [145 BUBBLE] [146 DIZZY PUNCH] [147 SPORE] [148 FLASH] [149 PSYWAVE] [150 SPLASH] [151 ACID ARMOR] [152 CRABHAMMER] [153 EXPLOSION] [154 FURY SWIPES] [155 BONEMERANG] [156 REST] [157 ROCK SLIDE] [158 HYPER FANG] [159 SHARPEN] [160 CONVERSION] [161 TRI ATTACK] [162 SUPER FANG] [163 SLASH] [164 SUBSTITUTE] [165 STRUGGLE])

 : 

 : (5 13 14 18 25 92 32 34 36 38 61 55 58 59 63 6 66 68 69 99 72 76 82 85 87 89 90 91 94 100 102 104 115 117 118 120 121 126 129 130 135 138 143 156 86 149 153 157 161 164 15 19 57 70 148)

 : (MEGA PUNCH . RAZOR WIND . SWORDS DANCE . WHIRLWIND . MEGA KICK . TOXIC . HORN DRILL . BODY SLAM . TAKE DOWN . DOUBLE-EDGE . BUBBLEBEAM . WATER GUN . ICE BEAM . BLIZZARD . HYPER BEAM . PAY DAY . SUBMISSION . COUNTER . SEISMIC TOSS . RAGE . MEGA DRAIN . SOLARBEAM . DRAGON RAGE . THUNDERBOLT . THUNDER . EARTHQUAKE . FISSURE . DIG . PSYCHIC . TELEPORT . MIMIC . DOUBLE TEAM . REFLECT . BIDE . METRONOME . SELFDESTRUCT . EGG BOMB . FIRE BLAST . SWIFT . SKULL BASH . SOFTBOILED . DREAM EATER . SKY ATTACK . REST . THUNDER WAVE . PSYWAVE . EXPLOSION . ROCK SLIDE . TRI ATTACK . SUBSTITUTE . CUT . FLY . SURF . STRENGTH . FLASH)

 

 

 ***

 #+name: machines

 #+begin_src clojure

 (defn hxc-machines

   "The hardcoded moves taught by TMs and HMs. List begins at ROM@1232D."

   ([] (hxc-machines

        com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [moves (hxc-move-names rom)]

        (zipmap

         (range)

         (take-while

             (comp not nil?)

             (map (comp

                   format-name

                   (zipmap

                    (range)

                    moves)

               dec)

                  (take 100

                        (drop 0x1232D rom))))))))

 

 #+end_src

 

 

 

 

 

 ** COMMENT Status ailments

 

 * Places

 ** Names of places

 

 #+name: places

 #+begin_src clojure

 (def hxc-places

   "The hardcoded place names in memory. List begins at

 ROM@71500. [Cinnabar] Mansion seems to be dynamically calculated."

   (hxc-thunk-words 0x71500 560))

 

 #+end_src

 

 ** Wild Pok\eacute{}mon demographics

 #+name: wilds

 #+begin_src clojure

 

 

 

 (defn hxc-ptrs-wild

   "A list of the hardcoded wild encounter data in memory. Pointers

   begin at ROM@0CB95; data begins at ROM@0x04D89" 

   ([] (hxc-ptrs-wild com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [ptrs

            (map (fn [[a b]] (+ a (* 0x100 b)))

             (take-while (partial not= (list 0xFF 0xFF))

                             (partition 2 (drop 0xCB95 rom))))]

        ptrs)))

 

 

 

 (defn hxc-wilds

   "A list of the hardcoded wild encounter data in memory. Pointers

   begin at ROM@0CB95; data begins at ROM@0x04D89" 

   ([] (hxc-wilds com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (let [pokenames (zipmap (range) (hxc-pokenames rom))]

        (map

         (partial map (fn [[a b]] {:species (pokenames (dec b)) :level

                                   a}))

         (partition 10

                      

                       (take-while (comp (partial not= 1)

                                         first) 

                                  (partition 2

                                             (drop 0xCD8C rom))

                    

                    ))))))

 

 #+end_src

 

 

 

 

 

 * Appendices

 

 

 

 ** Mapping the ROM

 

 | ROM address (hex) | Description     | Format          | Example         |

 |-------------------+-----------------+-----------------+-----------------|

 |                   | <15>            | <15>            | <15>            |

 | 0233C-            | Shop inventories. |                 |                 |

 | 04495-            | Prices of items. | Each price is two bytes of binary-coded decimal. Prices are separated by zeroes. Priceless items[fn::Like the Pok\eacute{}dex and other unsellable items.] are given a price of zero. | The cost of lemonade is 0x03 0x50, which translates to a price of ₱350. |

 | 045B7-0491E       | Names of the items in memory. | Variable-length item names (strings of character codes). Names are separated by a single 0x50 character. | MASTER BALL#ULTRA BALL#... |

 | 04D89-            | Lists of wild Pok\eacute{}mon to encounter in each region. | Each list contains ten Pokemon (ids) and their levels; twenty bytes in total. First, the level of the first Pokemon. Then the internal id of the first Pokemon. Next, the level of the second Pokemon, and so on. Since Pokemon cannot have level 0, the lists are separated by a pair 0 /X/, where /X/ is an apparently random Pokemon id. | The first list is (3 36 4 36 2 165 3 165 2 36 3 36 5 36 4 165 6 36 7 36 0 25), i.e. level 3 pidgey, level 4 pidgey, level 2 rattata, level 3 rattata, level 2 pidgey, level 3 pidgey, level 5 pidgey, level 4 rattata, level 6 pidgey, level 7 pidgey, \ldquo{}level 0 gastly\rdquo{} (i.e., end-of-list). |

 | 05EDB.            | Which Pok\eacute{}mon to show during Prof. Oak's introduction. | A single byte, the Pok\eacute{}mon's internal id. | In Pok\eacute{}mon Yellow, it shows Pikachu during the introduction; Pikachu's internal id is 0x54. |

 | 06698-            | ? Background music. |                 |                 |

 | 0822E-082F?       | Pointers to background music, part I. |                 |                 |

 | 0CB95-            | Pointers to lists of wild pokemon to encounter in each region. These lists begin at 04D89, see above. | Each pointer is a low-byte, high-byte pair. | The first entry is 0x89 0x4D, corresponding to the address 0x4D89, the location of the first list of wild Pok\eacute{}mon (see 04D89, above). |

 |-------------------+-----------------+-----------------+-----------------|

 | 0DADB.            | Amount of HP restored by Hyper Potion. | The HP consists of a single byte. TODO: Discover what the surrounding data does, and find the data for the amount of HP restored by other items: Fresh Water (50HP), Soda (60HP), Lemonade(80HP). | 200             |

 | 0DAE0.            | Amount of HP restored by Super Potion. | "               | 50              |

 | 0DAE3.            | Amount of HP restored by Potion. | "               | 20              |

 |-------------------+-----------------+-----------------+-----------------|

 | 0DD4D-DD72        | Names of permanent stats. | Variable-length strings separated by 0x50. | #HEALTH#ATTACK#DEFENSE#SPEED#SPECIAL# |

 | 1195C-1196A       | The two terms for being able/unable to learn a TM/HM. | Variable-length strings separated by 0x50. | ABLE#NOT ABLE#  |

 | 119C0-119CE       | The two terms for being able/unable to evolve using the current stone. | Variable-length strings separated by 0x50. | ABLE#NOT ABLE#  |

 | 1232D-12364       | Which moves are taught by the TMs and HMs | A list of 55 move ids (50 TMs, plus 5 HMs). First, the move that will be taught by TM01; second, the move that will be taught by TM02; and so on. The last five entries are the moves taught by HMs 1-5. (See also, BC000 below) | The first few entries are (5 13 14 18 ...) corresponding to Mega Punch (TM01), Razor Wind (TM02), Swords Dance (TM03), Whirlwind (TM04), ... |

 |-------------------+-----------------+-----------------+-----------------|

 | 27D56 & 27D57.    | Pointer to the list of type pointers. |                 |                 |

 | 27D63-27D99       | Pointers to type names. | Each point is a low-byte, high-byte pair. The names of types follows immediately after this section; see below. | The first pointer is [0x99 0x7D], corresponding to the location 0x2.7D.99, the NORMAL type. |

 | 27D99-27DFF       | Names of the Pok\eacute{}mon types. | Variable-length type names (strings of character codes). Names are separated by a single 0x50 character. | NORMAL#FIGHTING#... |

 | 27E77-            | Trainer title names. | Variable-length names separated by 0x50. | YOUNGSTER#BUG CATCHER#LASS#... |

 | 34000-            |                 |                 |                 |

 | 38000-383DE       | The basic properties and effects of moves. (165 moves total) | Fixed-length (6 byte) continguous descriptions (no separating character): move-index, move-effect, power, move-type, accuracy, pp. | The entry for Pound, the first attack in the list, is (1 0 40 0 255 35). See below for more explanation. |

 | 383DE-            | Species data for the Pokemon, listed in Pokedex order: Pokedex number; base moves; types; learnable TMs and HMs; base HP, attack, defense, speed, special; sprite data. |                 |                 |

 | 39462-            | The Pok\eacute{}mon cry data. | Fixed-length (3 byte) descriptions of cries. |                 |

 | 3B1E5-            | Pointers to evolution/learnset data. |                 |                 |

 | 3B361-            | Evolution and learnset data. [fn::Evolution data consists of how to make Pok\eacute{}mon evolve, and what they evolve into. Learnset data consists of the moves that Pok\eacute{}mon learn as they level up.] | Variable-length evolution information (see below), followed by a list of level/move-id learnset pairs. |                 |

 | 40687-            | Species data from the Pok\eacute{}dex: species name, height, weight, etc. | Fixed-length sequences of bytes. See below for specifics. |                 |

 | 410B1-            | A conversion table between internal order and Pokedex order. |                 |                 |

 | 5DE10-5DE30       | Abbreviations for status ailments. | Fixed-length strings, probably[fn::Here's something strange: all of the status messages start with 0x7F and end with 0x4F \mdash{}except PAR, which ends with 0x50.]. The last entry is QUIT##. | [0x7F] *SLP* [0x4E][0x7F] *PSN* [0x4E][0x7F] *PAR* [0x50][0x7F]... |

 | 71500-            | Names of places. |                 |                 |

 | 7C249-7C2??       | Pointers to background music, pt II. |                 |                 |

 | 98000-            | Dialogue        |                 |                 |

 | B8000-            | The text of each Pokemon's Pok\eacute{}dex entry. |                 |                 |

 | BC000-BC60E       | Move names.     | Variable-length move names, separated by 0x50. The moves are in internal order. | POUND#KARATE CHOP#DOUBLESLAP#COMET PUNCH#... |

 | E8000-E876C       | Names of the \ldquo{}190\rdquo{} species of Pok\eacute{}mon in memory. | Fixed length (10-letter) Pok\eacute{}mon names. Any extra space is padded with the character 0x80. The names are in \ldquo{}internal order\rdquo{}. | RHYDON####KANGASKHANNIDORAN♂#... |

 |                   |                 |                 |                 |

 |                   |                 |                 |                 |

 

 

 

 ** Internal Pok\eacute{}mon IDs

 ** Type IDs

 

 #+name: type-ids

 #+begin_src clojure

 (def pkmn-types

   [:normal    ;;0

    :fighting  ;;1

    :flying    ;;2

    :poison    ;;3

    :ground    ;;4

    :rock      ;;5

    :bird      ;;6

    :bug       ;;7

    :ghost     ;;8

    :A

    :B

    :C

    :D

    :E

    :F

    :G

    :H

    :I

    :J

    :K

    :fire     ;;20 (0x14)

    :water    ;;21 (0x15)

    :grass    ;;22 (0x16)

    :electric ;;23 (0x17)

    :psychic  ;;24 (0x18)

    :ice      ;;25 (0x19)

    :dragon   ;;26 (0x1A)

    ])

 #+end_src

 

 ** Basic effects of moves

 

 *** Table of basic effects

 

 The possible effects of moves in Pok\eacute{}mon \mdash{} for example, dealing

 damage, leeching health, or potentially poisoning the opponent

 \mdash{} are stored in a table. Each move has exactly one effect, and

 different moves might have the same effect.

 

 For example, Leech Life, Mega Drain, and Absorb all have effect ID #3, which is \ldquo{}Leech half of the inflicted damage.\rdquo{}

 

 All the legitimate move effects are listed in the table

 below. Here are some notes for reading it:

 

 - Whenever an effect has a chance of doing something (like a chance of

   poisoning the opponent), I list the chance as a hexadecimal amount

   out of 256; this is to avoid rounding errors. To convert the hex amount into a percentage, divide by 256.

 - For some effects, the description is too cumbersome to

   write. Instead, I just write a move name

   in parentheses, like: (leech seed). That move gives a characteristic example

   of the effect.

 - I use the abbreviations =atk=, =def=, =spd=, =spc=, =acr=, =evd= for

   attack, defense, speed, special, accuracy, and evasiveness. 

 .

 

 

 

 | ID (hex) | Description                                                                                     | Notes                                                            |

 |----------+-------------------------------------------------------------------------------------------------+------------------------------------------------------------------|

 |        0 | normal damage                                                                                   |                                                                  |

 |        1 | no damage, just sleep                                                                           | TODO: find out how many turns                                    |

 |        2 | 0x4C chance of poison                                                                           |                                                                  |

 |        3 | leech half of inflicted damage                                                                  |                                                                  |

 |        4 | 0x19 chance of burn                                                                             |                                                                  |

 |        5 | 0x19 chance of freeze                                                                           |                                                                  |

 |        6 | 0x19 chance of paralysis                                                                        |                                                                  |

 |        7 | user faints; opponent's defense is halved during attack.                                        |                                                                  |

 |        8 | leech half of inflicted damage ONLY if the opponent is asleep                                   |                                                                  |

 |        9 | imitate last attack                                                                             |                                                                  |

 |        A | user atk +1                                                                                     |                                                                  |

 |        B | user def +1                                                                                     |                                                                  |

 |        C | user spd +1                                                                                     |                                                                  |

 |        D | user spc +1                                                                                     |                                                                  |

 |        E | user acr +1                                                                                     | This effect is unused.                                           |

 |        F | user evd +1                                                                                     |                                                                  |

 |       10 | get post-battle money = 2 * level * uses                                                        |                                                                  |

 |       11 | move has 0xFE acr, regardless of battle stat modifications.                                     |                                                                  |

 |       12 | opponent atk -1                                                                                 |                                                                  |

 |       13 | opponent def -1                                                                                 |                                                                  |

 |       14 | opponent spd -1                                                                                 |                                                                  |

 |       15 | opponent spc -1                                                                                 |                                                                  |

 |       16 | opponent acr -1                                                                                 |                                                                  |

 |       17 | opponent evd -1                                                                                 |                                                                  |

 |       18 | converts user's type to opponent's.                                                             |                                                                  |

 |       19 | (haze)                                                                                          |                                                                  |

 |       1A | (bide)                                                                                          |                                                                  |

 |       1B | (thrash)                                                                                        |                                                                  |

 |       1C | (teleport)                                                                                      |                                                                  |

 |       1D | (fury swipes)                                                                                   |                                                                  |

 |       1E | attacks 2-5 turns                                                                               | Unused. TODO: find out what it does.                             |

 |       1F | 0x19 chance of flinching                                                                        |                                                                  |

 |       20 | opponent sleep for 1-7 turns                                                                    |                                                                  |

 |       21 | 0x66 chance of poison                                                                           |                                                                  |

 |       22 | 0x4D chance of burn                                                                             |                                                                  |

 |       23 | 0x4D chance of freeze                                                                           |                                                                  |

 |       24 | 0x4D chance of paralysis                                                                        |                                                                  |

 |       25 | 0x4D chance of flinching                                                                        |                                                                  |

 |       26 | one-hit KO                                                                                      |                                                                  |

 |       27 | charge one turn, atk next.                                                                      |                                                                  |

 |       28 | fixed damage, leaves 1HP.                                                                       | Is the fixed damage the power of the move?                       |

 |       29 | fixed damage.                                                                                   | Like seismic toss, dragon rage, psywave.                         |

 |       2A | atk 2-5 turns; opponent can't attack                                                            | The odds of attacking for /n/ turns are: (0 0x60 0x60 0x20 0x20) |

 |       2B | charge one turn, atk next. (can't be hit when charging)                                         |                                                                  |

 |       2C | atk hits twice.                                                                                 |                                                                  |

 |       2D | user takes 1 damage if misses.                                                                  |                                                                  |

 |       2E | evade status-lowering effects                                                                   | Caused by you or also your opponent?                             |

 |       2F | broken: if user is slower than opponent, makes critical hit impossible, otherwise has no effect | This is the effect of Focus Energy. It's (very) broken.          |

 |       30 | atk causes recoil dmg = 1/4 dmg dealt                                                           |                                                                  |

 |       31 | confuses opponent                                                                               |                                                                  |

 |       32 | user atk +2                                                                                     |                                                                  |

 |       33 | user def +2                                                                                     |                                                                  |

 |       34 | user spd +2                                                                                     |                                                                  |

 |       35 | user spc +2                                                                                     |                                                                  |

 |       36 | user acr +2                                                                                     | This effect is unused.                                           |

 |       37 | user evd +2                                                                                     | This effect is unused.                                           |

 |       38 | restores up to half of user's max hp.                                                           |                                                                  |

 |       39 | (transform)                                                                                     |                                                                  |

 |       3A | opponent atk -2                                                                                 |                                                                  |

 |       3B | opponent def -2                                                                                 |                                                                  |

 |       3C | opponent spd -2                                                                                 |                                                                  |

 |       3D | opponent spc -2                                                                                 |                                                                  |

 |       3E | opponent acr -2                                                                                 |                                                                  |

 |       3F | opponent evd -2                                                                                 |                                                                  |

 |       40 | doubles user spc when attacked                                                                  |                                                                  |

 |       41 | doubles user def when attacked                                                                  |                                                                  |

 |       42 | just poisons opponent                                                                           |                                                                  |

 |       43 | just paralyzes opponent                                                                         |                                                                  |

 |       44 | 0x19 chance opponent atk -1                                                                     |                                                                  |

 |       45 | 0x19 chance opponent def -1                                                                     |                                                                  |

 |       46 | 0x19 chance opponent spd -1                                                                     |                                                                  |

 |       47 | 0x4C chance opponent spc -1                                                                     |                                                                  |

 |       48 | 0x19 chance opponent acr -1                                                                     |                                                                  |

 |       49 | 0x19 chance opponent evd -1                                                                     |                                                                  |

 |       4A | ???                                                                                             | ;; unused? no effect?                                            |

 |       4B | ???                                                                                             | ;; unused? no effect?                                            |

 |       4C | 0x19 chance of confusing the opponent                                                           |                                                                  |

 |       4D | atk hits twice. 0x33 chance opponent poisioned.                                                 |                                                                  |

 |       4E | broken. crash the game after attack.                                                            |                                                                  |

 |       4F | (substitute)                                                                                    |                                                                  |

 |       50 | unless opponent faints, user must recharge after atk. some exceptions apply                     |                                                                  |

 |       51 | (rage)                                                                                          |                                                                  |

 |       52 | (mimic)                                                                                         |                                                                  |

 |       53 | (metronome)                                                                                     |                                                                  |

 |       54 | (leech seed)                                                                                    |                                                                  |

 |       55 | does nothing (splash)                                                                           |                                                                  |

 |       56 | (disable)                                                                                       |                                                                  |

 #+end_src

 

 *** Source

 #+name: move-effects

 #+begin_src clojure

 (def move-effects

   ["normal damage"

    "no damage, just opponent sleep" ;; how many turns? is atk power ignored?

    "0x4C chance of poison"

    "leech half of inflicted damage"

    "0x19 chance of burn"

    "0x19 chance of freeze"

    "0x19 chance of paralyze"

    "user faints; opponent defense halved during attack."

    "leech half of inflicted damage ONLY if sleeping opponent."

    "imitate last attack"

    "user atk +1"

    "user def +1"

    "user spd +1"

    "user spc +1"

    "user acr +1" ;; unused?!

    "user evd +1"

    "get post-battle $ = 2*level*uses"

    "0xFE acr, no matter what."

    "opponent atk -1"     ;; acr taken from move acr?

    "opponent def -1"     ;;

    "opponent spd -1"   ;;

    "opponent spc -1" ;;

    "opponent acr -1";;

    "opponent evd -1"

    "converts user's type to opponent's."

    "(haze)"

    "(bide)"

    "(thrash)"

    "(teleport)"

    "(fury swipes)"

    "attacks 2-5 turns" ;; unused? like rollout?

    "0x19 chance of flinch"

    "opponent sleep for 1-7 turns"

    "0x66 chance of poison"

    "0x4D chance of burn"

    "0x4D chance of freeze"

    "0x4D chance of paralyze"

    "0x4D chance of flinch"

    "one-hit KO"

    "charge one turn, atk next."

    "fixed damage, leaves 1HP." ;; how is dmg determined?

    "fixed damage."             ;; cf seismic toss, dragon rage, psywave.

    "atk 2-5 turns; opponent can't attack" ;; unnormalized? (0 0x60 0x60 0x20 0x20)

    "charge one turn, atk next. (can't be hit when charging)"

    "atk hits twice."

    "user takes 1 damage if misses."

    "evade status-lowering effects" ;;caused by you or also your opponent?

    "(broken) if user is slower than opponent, makes critical hit impossible, otherwise has no effect"

    "atk causes recoil dmg = 1/4 dmg dealt"

    "confuses opponent" ;; acr taken from move acr

    "user atk +2"

    "user def +2"

    "user spd +2"

    "user spc +2"

    "user acr +2" ;; unused!

    "user evd +2" ;; unused!

    "restores up to half of user's max hp." ;; broken: fails if the difference

    ;; b/w max and current hp is one less than a multiple of 256.

    "(transform)"

    "opponent atk -2"

    "opponent def -2"

    "opponent spd -2"

    "opponent spc -2"

    "opponent acr -2"

    "opponent evd -2"

    "doubles user spc when attacked"

    "doubles user def when attacked"

    "just poisons opponent"   ;;acr taken from move acr

    "just paralyzes opponent" ;;

    "0x19 chance opponent atk -1"

    "0x19 chance opponent def -1"

    "0x19 chance opponent spd -1"

    "0x4C chance opponent spc -1" ;; context suggest chance is 0x19

    "0x19 chance opponent acr -1"

    "0x19 chance opponent evd -1"

    "???" ;; unused? no effect?

    "???" ;; unused? no effect?

    "0x19 chance opponent confused"

    "atk hits twice. 0x33 chance opponent poisioned."

    "broken. crash the game after attack."

    "(substitute)"

    "unless opponent faints, user must recharge after atk. some

   exceptions apply."

    "(rage)"

    "(mimic)"

    "(metronome)"

    "(leech seed)"

    "does nothing (splash)"

    "(disable)"

    ])

 #+end_src

 

 

 ** Alphabet code

 

 * Source

 

 #+begin_src clojure :tangle ../clojure/com/aurellem/gb/hxc.clj

 

 (ns com.aurellem.gb.hxc

   (:use (com.aurellem.gb assembly characters gb-driver util mem-util

                          constants species))

   (:import [com.aurellem.gb.gb_driver SaveState]))

 

 ; ************* HANDWRITTEN CONSTANTS

 

 <<type-ids>>

 

 

 ;; question: when status effects claim to take

 ;; their accuracy from the move accuracy, does

 ;; this mean that the move always "hits" but the

 ;; status effect may not?

 

 <<move-effects>>

 

 ;; ************** HARDCODED DATA

 

 <<hxc-thunks>>

 ;; --------------------------------------------------

 

 <<pokenames>>

 <<type-names>>

 

 ;; http://hax.iimarck.us/topic/581/

 <<pokecry>>

 

 

 <<item-names>>

 

 

 

 (def hxc-titles

   "The hardcoded names of the trainer titles in memory. List begins at

 ROM@27E77"

   (hxc-thunk-words 0x27E77 196))

 

 

 <<dex-text>>

 

 ;; In red/blue, pokedex stats are in internal order.

 ;; In yellow, pokedex stats are in pokedex order.

 <<dex-stats>>

 

 

 

 

 <<places>>

 

 (defn hxc-dialog

   "The hardcoded dialogue in memory, including in-game alerts. Dialog

   seems to be separated by 0x57 instead of 0x50 (END). Begins at ROM@98000."

   ([rom]

      (map character-codes->str

           (take-nth 2

                     (partition-by #(= % 0x57)

                                   (take 0x0F728

                                         (drop 0x98000 rom))))))

   ([]

      (hxc-dialog com.aurellem.gb.gb-driver/original-rom)))

 

 

 <<move-names>>

 <<move-data>>

 

 <<machines>>

 

 

 

 (defn internal-id

   ([rom]

      (zipmap 

       (hxc-pokenames rom)

       (range)))

   ([]

      (internal-id com.aurellem.gb.gb-driver/original-rom)))

 

 

 

 

 

 ;; nidoran gender change upon levelup

 ;; (->

 ;;  @current-state

 ;;  rom

 ;;  vec

 ;;  (rewrite-memory

 ;;   (nth (hxc-ptrs-evolve) ((internal-id) :nidoran♂))

 ;;   [1 1 15])

 ;;  (rewrite-memory

 ;;   (nth (hxc-ptrs-evolve) ((internal-id) :nidoran♀))

 ;;   [1 1 3])

 ;;  (write-rom!)

 

 ;;  )

 

 

 

 <<type-advantage>>

 

 

 

 <<evolution-header>>

 <<evolution>>

 <<learnsets>>

 <<pokebase>>

   

   

 (defn hxc-intro-pkmn

   "The hardcoded pokemon to display in Prof. Oak's introduction; the pokemon's

 internal id is stored at ROM@5EDB."

   ([] (hxc-intro-pkmn

        com.aurellem.gb.gb-driver/original-rom))

   ([rom]

      (nth (hxc-pokenames rom) (nth rom 0x5EDB))))

 

 (defn sxc-intro-pkmn!

   "Set the hardcoded pokemon to display in Prof. Oak's introduction."

   [pokemon]

   (write-rom! 

    (rewrite-rom 0x5EDB

                 [

                  (inc

                   ((zipmap

                     (hxc-pokenames)

                     (range))

                    pokemon))])))

   

 

 <<item-prices>>

 

 <<item-vendors>>

 

 <<wilds>>

 

 

 ;; ********************** MANIPULATION FNS

 

 

 (defn same-type

   ([pkmn move]

      (same-type

       com.aurellem.gb.gb-driver/original-rom pkmn move))

   ([rom pkmn move]

      (((comp :types (hxc-pokemon-base rom)) pkmn)

       ((comp :type (hxc-move-data rom)) move))))

 

 

 

 

 (defn submap?

   "Compares the two maps. Returns true if map-big has the same associations as map-small, otherwise false." 

   [map-small map-big]

   (cond (empty? map-small) true

         (and

          (contains? map-big (ffirst map-small))

          (= (get map-big (ffirst map-small))

             (second (first map-small))))

         (recur (next map-small) map-big)

 

         :else false))  

 

 

 (defn search-map [proto-map maps]

   "Returns all the maps that make the same associations as proto-map."

   (some (partial submap? proto-map) maps))

 

 (defn filter-vals

   "Returns a map consisting of all the pairs [key val] for

   which (pred key) returns true."

   [pred map]

   (reduce (partial apply assoc) {}

           (filter (fn [[k v]] (pred v)) map)))

 

 

 (defn search-moves

   "Returns a subcollection of all hardcoded moves with the

   given attributes. Attributes consist of :name :power

   :accuracy :pp :fx-id

   (and also :fx-txt, but it contains the same information

   as :fx-id)"

   ([attribute-map]

      (search-moves

       com.aurellem.gb.gb-driver/original-rom attribute-map))

   ([rom attribute-map]

      (filter-vals (partial submap? attribute-map)

                   (hxc-move-data rom))))

 

 

 

 

 

 ;; note: 0x2f31 contains the names "TM" "HM"?

 

 ;; note for later: credits start at F1290

 

 ;; note: DADB hyper-potion-hp _ _ _ super-potion-hp _ _ _ potion-hp ??

 

 ;; note: DD4D spells out pokemon vital stat names ("speed", etc.)

 

 ;; note: 1195C-6A says ABLE#NOT ABLE#, but so does 119C0-119CE.

 ;; The first instance is for Machines; the second, for stones.

 

 ;; 0x251A (in indexable mem): image decompression routine seems to begin here.

 

 

 ;; Note: There are two tile tables, one from 8000-8FFF, the other from

 ;; 8800-97FF. The latter contains symbols, possibly map tiles(?), with some japanese chars and stuff at the end. 

 (defn print-pixel-letters!

   "The pixel tiles representing letters. Neat!"

  ([] (print-pixel-letters! (read-state "oak-speaks"))) 

 ([state] 

    (map

     (comp

      println

      (partial map #(if (zero? %) \space 0))

      #(if (< (count %) 8)

         (recur (cons 0 %))

         %)

      reverse bit-list)

     

     (take 0xFFF (drop 0x8800 (memory state))))))

 

 

 (defn test-2 []

   (loop [n 0

          pc-1 (pc-trail (-> state-defend (tick) (step [:a]) (step [:a]) (step []) (nstep 100)) 100000)

          pc-2 (pc-trail (-> state-speed (tick) (step [:a]) (step [:a])

   (step []) (nstep 100)) 100000)]

     (cond (empty? (drop n pc-1)) [pc-1 n]

           (not= (take 10 (drop n pc-1)) (take 10 pc-2))

           (recur  pc-1 pc-2 (inc n))

           :else

           [(take 1000 pc-2) n])))

 

 

 

 

 

 

 

 (comment 

 

 (def hxc-later

   "Running this code produces, e.g. hardcoded names NPCs give

 their pokemon. Will sort through it later."

 (print (character-codes->str(take 10000

                           (drop 0x71597

                                 (rom (root)))))))

 

 (let [dex

       (partition-by #(= 0x50 %)

                     (take 2540

                           (drop 0x40687

                                 (rom (root)))))]

   (def dex dex)

   (def hxc-species

     (map character-codes->str

          (take-nth 4 dex))))

 )

 

 

 #+end_src

 

 #+results:

 : nil