(ns com.aurellem.run.bootstrap-0

   (:use (com.aurellem.gb saves gb-driver util

                          items vbm characters money))

   (:use (com.aurellem.run util title save-corruption))

   (:use (com.aurellem.exp item-bridge))

   (:import [com.aurellem.gb.gb_driver SaveState]))

 

 (defn-memo boot-root []

   [ [] (root)])

   

 (defn-memo to-rival-name

   ([] (to-rival-name (boot-root)))

   ([script]

      (->> script

          title

          oak

          name-entry-rlm

          (scroll-text 5))))

 

 (defn-memo name-rival-bootstrap

   ([] (name-rival-bootstrap (to-rival-name)))

   ([script]

      (->> script

          (first-difference [] [:a] AF)

          (first-difference [] [:r] DE)

          (play-moves

           [[]

            [] [] [:r] [] [:d] [:a]           ;; L

            [:r] [] [:r] [] [:r] [] [:r] [] 

            [:r] [] [:d] [] [:d] [:a]         ;; [PK]

            [:u] [] [:l] [] [:l] [] [:l] []

            [:l] [] [:l] [] [:a]              ;; U

            [:r] [] [:r] [] [:r] [] [:r] []

            [:r] [] [] [:d] [:a]              ;; [PK]

            [] [:a]                           ;; [PK]

            [] [:a]                           ;; [PK]

            [:r] [] [:d] [:a]                 ;; END

            ]))))

 

 ;; (defn-memo name-rival-bootstrap

 ;;   ([] (name-rival-bootstrap (to-rival-name)))

 ;;   ([script]

 ;;      (->> script

 ;;          (first-difference [] [:a] AF)

 ;;          (first-difference [] [:r] DE)

 ;;          (play-moves

 ;;           [[]

 ;;            [] [] [:r] []           

 ;;            [:r] [] [:r] [] [:r] [] [:r] []

 ;;            [:r] [] [:d] [] [:d] [] [:d] [:a];; PK

 ;;            [] [:a]                          ;; PK

 ;;            [:u] [] [:l] [] [:l] [] [:l] []

 ;;            [:l] [] [:l] [:a]                ;; U

 ;;            [:d] [] [:r] [] [:r] [] [:r] []

 ;;            [:r] [] [:r] [:a]                ;; PK

 ;;            [:u] [] [:l] [] [:l] [] [:l] []

 ;;            [:l] [] [:l] [] [:u] [:a]        ;; L

 ;;            [:d] [] [:r] [] [:r] [] [:r] []

 ;;            [:r] [] [:r] [] [:d] [:a]        ;; PK

 ;;            [:r] [] [:d] [:a]                ;; END

 ;;            ]))))

 

 (defn-memo leave-house

   ([] (leave-house (name-rival-bootstrap)))

   ([script]

      (->> script

           finish-title

           walk-to-stairs

           walk-to-door

           (walk [↓ ↓]))))

 

 (defn-memo to-pallet-town-edge

   ([] (to-pallet-town-edge (leave-house)))

   ([script]

      (->> script

           (walk [→ → → → →

                  ↑ ↑ ↑ ↑ ↑ ↑]))))

 

 (defn-memo start-pikachu-battle

   ([] (start-pikachu-battle

        (to-pallet-town-edge)))

   ([script]

      (->> script

           (first-difference [:b] [:b :a] DE)

           scroll-text

           (do-nothing 200)

           (play-moves [[:b]]))))

 

 (defn-memo capture-pikachu

   ([] (capture-pikachu (start-pikachu-battle)))

   ([script]

      (->> script

           (scroll-text 3))))

 

 (defn-memo go-to-lab

   ([] (go-to-lab (capture-pikachu)))

   ([script]

      (->> script

           end-text

           (scroll-text 5)

           end-text

           ;; oak walks you to his lab; no input required.

           (do-nothing 400))))

 

 (defn-memo talk-to-oak-in-lab

   ([] (talk-to-oak-in-lab (go-to-lab)))

   ([script]

      (->> script

           (scroll-text 14)

           end-text)))

 

 (defn-memo try-to-get-eevee

   ([] (try-to-get-eevee (talk-to-oak-in-lab)))

   ([script]

      (->> script

           ;; walk to pokeball

           (walk [↓ → →])

           ;; and try to grab it

           (play-moves

            (concat [↑ ↑ [:a]]

                    (repeat 100 [])))

           (scroll-text 10)

           (end-text))))

 

 (defn-memo obtain-pikachu

   ([] (obtain-pikachu (try-to-get-eevee)))

   ([script]

      (->> script

           (scroll-text 6)

           (end-text))))

   

           

 (defn-memo begin-battle-with-rival

   ([] (begin-battle-with-rival

         (obtain-pikachu)))

   ([script]

      (->> script

           (walk [↓ ↓ ↓])

           (scroll-text 3)

           (end-text)

           (scroll-text))))

 

 (defn-memo defeat-eevee

   ([] (defeat-eevee

         (begin-battle-with-rival)))

   ([script]

      (->> script

           (do-nothing 400)

           (play-moves [[:a]])

           (critical-hit)

           (do-nothing 200)

           (scroll-text 2) ;; for eevee's tail-whip

           (do-nothing 10)

           (play-moves [[:a]])

           (critical-hit)

           (do-nothing 200)

           (scroll-text 2) ;; tail whip again

           (do-nothing 10)

           (play-moves [[:a]])

           (critical-hit)

           (do-nothing 200))))

 

 (defn-memo finish-rival-text

   ([] (finish-rival-text

        (defeat-eevee)))

   ([script]

      (->> script

           (scroll-text 12)

           (end-text))))

 

 (defn-memo pikachu-comes-out

   ([] (pikachu-comes-out

        (finish-rival-text)))

   ([script]

      (->> script

           (scroll-text 8)

           (end-text))))

 

 (defn-memo leave-oaks-lab

   ([] (leave-oaks-lab

        (pikachu-comes-out)))

   ([script]

      (->> script 

           (walk [↓ ↓ ↓ ↓ ↓ ↓]))))

 

 (defn-memo oaks-lab->pallet-town-edge

   ([] (oaks-lab->pallet-town-edge

        (leave-oaks-lab)))

   ([script]

      (->> script

           (walk [← ← ←

                  ↑ ↑ ↑ ↑ ↑ ↑ ↑ ↑ ↑ ↑ →]))))

 

 (defn-memo pallet-edge->viridian-mart

   ([] (pallet-edge->viridian-mart true

        (oaks-lab->pallet-town-edge)))

   ([dodge-stupid-guy? script]

      (let [dodge-1 (if dodge-stupid-guy?

                     [→ →]

                     [→])

            dodge-2 (if dodge-stupid-guy?

                      [↑ ↑ ←]

                      [↑ ↑])]

        

        (->> script

           ;; leave straight grass

           (walk-thru-grass

            [↑ ↑ ↑ ↑ ↑])

 

           (walk [↑ ↑ ↑ ↑])

 

           (walk-thru-grass

            [← ← ↑])

 

           (walk [↑ ↑ ↑ ↑ → → → ])

 

           (walk-thru-grass

            [→ ↑ ↑ ←])

 

           (walk

            [← ←

             ↑ ↑ ↑ ↑ ↑ ↑ ↑ ↑

             → → → → ])

 

           ;; this part is dependent on that

           ;; stupid NPC in the grass patch

           (walk-thru-grass

            (concat dodge-1

                 [↑ ↑ ↑ ↑ ↑ ↑ ↑ ↑ ]))

           

           (walk

            (concat

             dodge-2

             [← ← ←

              ↑ ↑ ↑ ↑ ↑ ↑ ↑ ↑ ↑ ↑

              ← ←

              ↑ ↑ ↑ ↑

              → → → → → → → → → →

              ↑ ↑ ↑ ↑ ↑ ↑ ↑])))))) 

             

 (defn-memo get-oaks-parcel

   ([] (get-oaks-parcel

        (pallet-edge->viridian-mart)))

   ([script]

      (->> script

           (do-nothing 50)

           (end-text)

           (scroll-text 3)

           (do-nothing 197)

           (play-moves [[:a] []])

           (walk [↓ ↓ → ↓]))))

 

 (defn-memo viridian-store->oaks-lab

   ([] (viridian-store->oaks-lab

        (get-oaks-parcel)))

   ([script]

      (->> script

           (walk [↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓

                  ← ← ← ← ← ← ← ← ← 

                  ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓

                  ← ←

                  ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓

                  ↓ ↓ ↓ ↓ ↓ ↓ ↓

                  → → → → → → → →

                  ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓

                  ← ← ← ← ←

                  ↓ ↓ ↓ ↓

                  ])

           (walk-thru-grass

            [↓ ↓ ↓ ↓ ↓ ↓ ↓])

           (walk [↓ ↓ ← ↓ ↓ ↓ ←

                  ↓ ↓ ↓ ↓ ↓ ↓

                  → → → ↑])

                 

           (do-nothing 1))))

 

                  

 (defn-memo viridian-store->oaks-lab-like-a-boss

   ([] (viridian-store->oaks-lab-like-a-boss

        (get-oaks-parcel)))

   ([script]

      (->> script

           (walk [↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓

                  ← ← ← ← ← ← ← ← ← 

                  ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓])

 

           (walk-thru-grass

            [↓ ↓ ↓ ↓ ↓])

 

           (walk

            [↓ ↓ ← ↓

             ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓

             → → → ↓])

 

           (walk-thru-grass

            [↓ ↓ ↓ ↓])

 

           (walk [← ← ↓ ↓ ↓ ↓ ↓ ↓])

           

           (walk-thru-grass

            [↓ ↓ ↓ ↓ ↓ ↓])

           

           (walk [↓ ↓ ↓ ← ↓ ↓ ↓ 

                  ↓ ↓ ↓ ↓ ↓

                  → → → ↑]))))

 

 (defn-memo deliver-oaks-parcel

   ([] (deliver-oaks-parcel

        (viridian-store->oaks-lab-like-a-boss)))

   ([script]

      (->> script

           (walk [↑ ↑ ↑ ↑ ↑ ↑ ↑ ↑])

           (play-moves [[] [:a]])

           (scroll-text 13)

           (end-text)

           (do-nothing 200)

           (scroll-text 2)

           (end-text)

           (scroll-text 2)

           (end-text)

           (scroll-text 8)

           (end-text)

           (scroll-text 9)

           (end-text)

           (scroll-text 7)

           (end-text)                    

           (walk [↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓]))))

 

 (defn-memo return-to-viridian-mart

   ([] (return-to-viridian-mart

        (deliver-oaks-parcel)))

   ([script]

      (->> script

           oaks-lab->pallet-town-edge

           (pallet-edge->viridian-mart false))))

 

 (defn-memo walk-to-counter

   ([] (walk-to-counter

        (return-to-viridian-mart)))

   ([script]

      (->> script 

           (walk [↑ ↑ ←]))))

 

 

 

 ;; useful addresses

 52262 ;; --- current-cursor-offset

 52278 ;; --- current screen-offset

 

 

 (defn exp-item-list []

   (clojure.pprint/pprint

    (apply harmonic-compare 

           (map read-state 

                ["up-1" "down-1"

                 "up-2" "down-2"

                 "up-3" "down-3"

                 "up-4" "down-4"

                 "up-5" "down-5"

                 "up-6"]))))

 

 

 ;; turns out that these addresses are the cursor position

 ;; for all lists in the game (start list, pokemon list, shop

 ;; lists, inventory lists, battle list, basically

 ;; everything!)

 

 (def list-cursor-offset-address 52262)

 (def list-screen-offset-address 52278)

 

 (defn list-offset

   ([^SaveState state]

      (let [mem (memory state)]

        (+ (aget mem list-screen-offset-address)

           (aget mem list-cursor-offset-address))))

   ([] (list-offset @current-state)))

 

 (defn exp-item-selection []

   (clojure.pprint/pprint

    (apply memory-compare

           (map read-state

                ["1-item" 

                 "2-items"

                 "3-items"

                 "4-items"

                 ]))))

 

 (def item-quantity-selected-address 65432)

 

 (defn item-quantity-selected

   ([^SaveState state]

      (println "items:" (aget (memory state) item-quantity-selected-address))

      (aget (memory state) item-quantity-selected-address))

   ([] (item-quantity-selected @current-state)))

 

 (defn set-cursor-relative

   "Assumes the arrow keys currently control the cursor.

    Moves the cursor n steps relative to its current

    position."

   [n script]

   (let [key (if (< 0 n) ↓ ↑)]

     (multiple-times

      (Math/abs n)

      (partial first-difference 

       [] key list-offset)

      script)))

 

 (defn set-cursor

   "Assumes the arrow keys currently control the cursor. Sets

    the cursor to the desired position. Works for any menu

    that uses a cursor including the start menu, item menu,

    pokemon menu, and battle menu."

   [n [moves state :as script]]

   (let [current-position (list-offset state)

         difference (- n current-position)]

     (println difference)

     (set-cursor-relative difference script)))

 

 (defn set-quantity

   "Set the quantity of an item to buy or sell to the desired value

   using the fewest possible button presses."

   ([total-quantity desired-quantity [moves state :as script]]

      (let [current-quantity (item-quantity-selected state)

            loop-point (if (> total-quantity 99) 0xFF 99)

            distance (- desired-quantity current-quantity)

            loop-distance (int(* -1 (Math/signum (float distance))

                                 (- loop-point (Math/abs distance))))

            best-path (first (sort-by #(Math/abs %)

                                      [distance loop-distance]))

            direction (if (< 0 best-path) ↑ ↓)]

        (println "best-path" best-path)

        (reduce

         (fn [script _]

           (delayed-difference [] direction 5 item-quantity-selected

                               script))

         

         script

         (range (Math/abs best-path)))))

   ([desired-quantity [moves state :as script]]

      (set-quantity 99 desired-quantity script)))

 

 (defn activate-start-menu [script]

   (first-difference [:b] [:b :start] AF script))

 

 (defn wait-until [script-fn script]

   (let [wait-time

         (- (dec (count (first (script-fn script))))

            (count (first script)))]

     (println "wait-time" wait-time)

     (do-nothing wait-time script)))

 

 (defn select-menu-entry [script]

   (->> script

        (wait-until (partial set-cursor-relative 1))

        (play-moves [[:a] []])))

 

 (defn-memo do-save-corruption

   ([] (do-save-corruption

        (walk-to-counter)))

   ([script]

      (->> script

           activate-start-menu

           (set-cursor 4)

           select-menu-entry

           select-menu-entry

           (play-moves

            ;; this section is copied from speedrun-2942 and corrupts

            ;; the save so that the total number of pokemon is set to

            ;; 0xFF, allowing manipulation of non-pokemon data in RAM

            ;; via the pokemon interface.

            [[] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [] []

             [] [] [] [] [] [] [] [] [] [] [] [:select] [:restart]])

           (title)

           (first-difference [] [:start] AF)

           (first-difference [] [:a] AF))))

           

 (defn gen-corrupted-checkpoint! []

   (let [[cor-moves cor-save] (do-save-corruption)]

     (write-moves! cor-moves "cor-checkpoint")

     (write-state! cor-save "cor-checkpoint")))

 

 (defn corrupted-checkpoint []

   [(read-moves "cor-checkpoint")

    (read-state "cor-checkpoint")])

 

 (def menu do-nothing )

 

 (defn close-menu [script]

   (first-difference [] [:b] AF script))

 

 

 

 ;; (defn select-menu-entry* [script]

 ;;   (let [wait-time

 ;;         (- (dec (count (first (set-cursor-relative 1 script))))

 ;;            (count (first script)))]

 ;;     (println "wait-time" wait-time)

 ;;     (play-moves (concat (repeat wait-time []) [[:a] []]) script)))

 

 

 (defn purchase-item

   "Assumes that the cursor is over the desired item, and purchases

    quantity of that item."

   [n script]

   (->> script

        select-menu-entry

        (set-quantity n)

        (first-difference [] [:a] AF)

        scroll-text

        select-menu-entry

        scroll-text))

 

 (defn-memo corrupt-item-list

   "Corrupt the num-of-items variable by switching a corrupted pokemon

    into out-of-bounds memory."

   ([] (corrupt-item-list

        ;;(corrupted-checkpoint)

        (do-save-corruption)

        ))

   ([script]

      (->> script

           activate-start-menu

           (set-cursor 1)        ; select "POKEMON" from

           select-menu-entry     ; from main menu.

           (set-cursor 5)        ; select 6th pokemon

           select-menu-entry

           (set-cursor 1)

           select-menu-entry     

           (repeat-until-different [] list-offset) 

           (set-cursor 9)

           select-menu-entry     ; switch 6th with 10th

           close-menu

           close-menu )))

 

 (defn-memo get-lots-of-money

   "Sell 0xFE cancel buttons to make a tremendous amount of money."

   ([] (get-lots-of-money (corrupt-item-list)))

   ([script]

      (->> script

           (first-difference [] [:a] AF) ; talk to shopkeep

           (repeat-until-different [] list-offset)

           (set-cursor 1)

           select-menu-entry

           (repeat-until-different [] list-offset)

           select-menu-entry

           (set-quantity 0xFF 0xF7)

           (first-difference [] [:a] AF)

           select-menu-entry

           close-menu

           )))

           

 

 (defn note [str script]

   (println str) script)

 

 (defn-memo buy-bootstrapping-items

   "Buy items that will become part of the bootstrapping

    program."

   ([] (buy-bootstrapping-items (get-lots-of-money)))

   ([script]

      (->> script

           close-menu

           select-menu-entry

           (purchase-item 1)        ; buying a pokeball overflows

                                    ; the item-counter from 0xFF to 0x00

                                    ; repairing the item-list.

           (set-cursor 1)   

           (purchase-item 1)        ; these other items are here to 

                                    ; protect the burn heals when the 

           (set-cursor 2)           ; item list is corrupted again.

           (purchase-item 1)

 

           (set-cursor 3)

           (purchase-item 1)

 

           (set-cursor 4)           ; 95 burn-heals spells out the

           (purchase-item 96)       ; return address to the pokemon

                                    ; kernel. 96 so that they can be

                                    ; deposited without causing a shift.

 

           close-menu               ; stop talking to shopkeep

           (wait-until select-menu-entry)

           (play-moves [[:b]])

           end-text)))

 

 (defn-memo corrupt-item-list-again

   ([] (corrupt-item-list-again (buy-bootstrapping-items)))

   ([script]

      (->> script

           activate-start-menu             

           (set-cursor-relative 0)                   

           select-menu-entry               

 

           ;; repair list-offset for pokemon-list

           (set-cursor-relative -1)

 

           (set-cursor 4)                  ; switching it to    

           select-menu-entry               ; tenth place.       

           (set-cursor 1)

           select-menu-entry               ; select "switch" on 5th

 

           (repeat-until-different [] list-offset)

           (set-cursor 9)                  ; goto 10th pokemon

           select-menu-entry               ; do switch

           close-menu

           close-menu)))

           

 (defn-memo viridian-store->viridian-poke-center

   ([] (viridian-store->viridian-poke-center

        (corrupt-item-list-again)))

   ([script]

      (->> script

           ;; leave store

           (walk [↓ ↓ 

                  → ↓ ↓])

           (walk [← ← ← 

                  ↓ ↓ ↓ ↓ ↓

                  ← ← ← ↑]))))

 

 (defn-memo to-poke-center-computer

   ([] (to-poke-center-computer

        (viridian-store->viridian-poke-center)))

   ([script]

      (->> script

           (walk [→ →

                  ↑ ↑ ↑

                  → → → → → → → → →])

           (do-nothing 1))))

 

 (defn-memo begin-deposits

   ([] (begin-deposits

        (to-poke-center-computer)))

   ([script]

      (->> script

           ;; access PC

           (scroll-text 2)

 

           ;; access item storage

           (menu [[:a] [:d] [:a]])

           (scroll-text 2)

 

           ;; begin deposit

           (menu [[:d] [:a]])

           (do-nothing 40))))

 

 (defn deposit-n-items

   [n script]

   (->> script

        (do-nothing 100)

        (play-moves [[:a]])

        (do-nothing 80)

        (multiple-times

         (dec n)

         (fn [script]

           (->> script

                (play-moves [[:u]])

                (do-nothing 1))))

        (play-moves [[:a]])

        (scroll-text)))

 

 (defn deposit-one-item

   [script]

   (->> script

        (do-nothing 100)

        (play-moves [[:a]])

        (do-nothing 80)

        (play-moves [[:a]])

        (scroll-text)))

 

 (defn-memo create-header

   ([] (create-header (begin-deposits)))

   ([script]

      (->> script

           (multiple-times 33 deposit-one-item)

           (do-nothing 1))))

 

 (defn bootstrap-init []

   [(read-moves "bootstrap-init")

    (read-state "bootstrap-init")])

 

 (defn create-bootstrap-program

   ([] (create-bootstrap-program

        (create-header)))

   ([script]

      (->> script

           (do-nothing 120)

           (menu [↓ ↓ ↓ ↓ ↓ ↓ ↓])

           ;;(deposit-n-items 33)

 

           (menu (repeat 17 ↓))

           

 

 

           (do-nothing 1))))

     

 

 (defn test-pc-item-program []

   (-> (read-state "bootstrap-init")

       (set-memory pc-item-list-start 50)

       (set-memory-range

        map-function-address-start [0x8B 0xD5])

       (set-memory-range

        (inc pc-item-list-start)

        (flatten

         [(repeat

           28

           [0xFF 0x01])

          [;;  second part of item manipulation program

           0x00   ;; this starts at address 0xD56C

           0x2A   ;; save (HL)=(target) to A, increment HL

 

           0x00

           0x47   ;; save A to B					

 

           0x00

           0x3A   ;; save (target+1) to A, decrement HL		

 

           0x00

           0x22   ;; A -> target, increment HL [(target+1) -> target]

 

           0x00

           0x70   ;; load B into target+1 [(target) -> target+1]	

 

           0x00

           0xC3   ;; first part of absolute jump

 

           0x0C   ;; return control to pokemon kernel

           0x5F]

          (repeat

           5

           [0xFF 0x01])

 

          [;; first part of item manipulation program

           0x00

           0x21   ;; load target + 1  into HL

 

           0x95   ;; this is the target address + 1

           0xD5

 

           0x00   ;; relative jump back to first part

           0x18   

 

           0xE1   ;; of program

           0x01

 

           0xFF   ;; spacer

           0x01

           

           0x04  ;; target ID        (pokeball)

           0x3E  ;; target Quantity  (lemonade)

           ]]))))