Mercurial > pygar

     1 /// The MIT License

     2 

     3 // Copyright (c) 2009 Massachusetts Institute of Technology

     4 

     5 // Permission is hereby granted, free of charge, to any person obtaining a copy

     6 // of this software and associated documentation files (the "Software"), to deal

     7 // in the Software without restriction, including without limitation the rights

     8 // to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

     9 // copies of the Software, and to permit persons to whom the Software is

    10 // furnished to do so, subject to the following conditions:

    11 

    12 // The above copyright notice and this permission notice shall be included in

    13 // all copies or substantial portions of the Software.

    14 

    15 // THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

    16 // IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

    17 // FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

    18 // AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

    19 // LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

    20 // OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN

    21 // THE SOFTWARE.

    22 

    23 

    24 import Connectable::*;

    25 import GetPut::*;

    26 import ClientServer::*;

    27 import RegFile::*;

    28 

    29 import FIFO::*;

    30 import FIFOF::*;

    31 import SFIFO::*;

    32 import RWire::*;

    33 

    34 import Trace::*;

    35 import BFIFO::*;

    36 import MemTypes::*;

    37 import ProcTypes::*;

    38 import BRegFile::*;

    39 import BranchPred::*;

    40 //import PathTypes::*;  This is only there to force the debugging

    41 

    42 //AWB includes

    43 `include "asim/provides/low_level_platform_interface.bsh"

    44 `include "asim/provides/soft_connections.bsh"

    45 `include "asim/provides/common_services.bsh"

    46 

    47 // Local includes

    48 //`include "asim/provides/processor_library.bsh" (included above directly)

    49 

    50 `include "asim/provides/common_services.bsh"

    51 `include "asim/dict/STATS_PROCESSOR.bsh"

    52 `include "asim/provides/processor_library.bsh"

    53 

    54 // Local includes. Look for the correspondingly named .awb files

    55 // workspace/labs/src/mit-6.375/modules/bluespec/mit-6.375/common/

    56 // to find the actual Bluespec files which are used to generate

    57 // these includes.  These files are specific to this audio processing

    58 // pipeline

    59 

    60 `include "asim/provides/audio_pipe_types.bsh"

    61 

    62 //interface CPUToHost;

    63 //  method Bit#(32) cpuToHost(int req);

    64 //endinterface

    65 

    66 interface Proc;

    67 

    68   // Interface from processor to caches

    69   interface Client#(DataReq,DataResp) dmem_client;

    70   interface Client#(InstReq,InstResp) imem_client;

    71 

    72   // Interface for enabling/disabling statistics on the rest of the core

    73   interface Get#(Bool) statsEn_get;

    74 

    75 //  // Interface to host

    76 //  interface CPUToHost tohost;

    77 

    78   // Interface to Audio Pipeline

    79   interface Get#(AudioProcessorUnit) sampleOutput;

    80   interface Put#(AudioProcessorUnit) sampleInput;

    81 	

    82 endinterface

    83 

    84 typedef enum { PCgen, Exec, Writeback } Stage deriving(Eq,Bits);

    85 

    86 //-----------------------------------------------------------

    87 // Register file module

    88 //-----------------------------------------------------------

    89 

    90 interface BRFile;

    91    method Action   wr( Rindx rindx, Bit#(32) data );

    92    method Bit#(32) rd1( Rindx rindx );

    93    method Bit#(32) rd2( Rindx rindx );

    94 endinterface

    95 

    96 module mkBRFile( BRFile );

    97    

    98    RegFile#(Rindx,Bit#(32)) rfile <- mkBRegFile();

    99    

   100    method Action wr( Rindx rindx, Bit#(32) data );

   101       rfile.upd( rindx, data );

   102    endmethod

   103    

   104    method Bit#(32) rd1( Rindx rindx );

   105       return ( rindx == 0 ) ? 0 : rfile.sub(rindx);

   106    endmethod

   107    

   108    method Bit#(32) rd2( Rindx rindx );

   109       return ( rindx == 0 ) ? 0 : rfile.sub(rindx);

   110    endmethod

   111 

   112 endmodule

   113 

   114 //-----------------------------------------------------------

   115 // Helper functions

   116 //-----------------------------------------------------------

   117 

   118 function Bit#(32) slt( Bit#(32) val1, Bit#(32) val2 );

   119    return zeroExtend( pack( signedLT(val1,val2) ) );

   120 endfunction

   121 

   122 function Bit#(32) sltu( Bit#(32) val1, Bit#(32) val2 );

   123    return zeroExtend( pack( val1 < val2 ) );

   124 endfunction

   125 

   126 function Bit#(32) rshft( Bit#(32) val );

   127    return zeroExtend(val[4:0]);

   128 endfunction

   129 

   130 

   131 //-----------------------------------------------------------

   132 // Find funct for wbQ

   133 //-----------------------------------------------------------

   134 function Bool findwbf(Rindx fVal, WBResult cmpVal);

   135   case (cmpVal) matches   

   136      tagged WB_ALU  {data:.res, dest:.rd} :

   137 	return (fVal == rd);

   138      tagged WB_Load .rd  :

   139 	return (fVal == rd);

   140      tagged WB_Store .st :

   141 	return False;

   142      tagged WB_Host .x   :

   143 	return False;

   144   endcase

   145 endfunction

   146 

   147      

   148 //-----------------------------------------------------------

   149 // Stall funct for wbQ

   150 //-----------------------------------------------------------

   151 function Bool stall(Instr inst, SFIFO#(WBResult, Rindx) f);

   152    case (inst) matches

   153       	 // -- Memory Ops ------------------------------------------------      

   154       tagged LW .it :

   155 	 return f.find(it.rbase);

   156       tagged SW {rsrc:.dreg, rbase:.addr, offset:.o} :

   157 	 return (f.find(addr) ||  f.find2(dreg));

   158 

   159 	 // -- Simple Ops ------------------------------------------------      

   160       tagged ADDIU .it : return f.find(it.rsrc);

   161       tagged SLTI  .it : return f.find(it.rsrc);

   162       tagged SLTIU .it : return f.find(it.rsrc);

   163       tagged ANDI  .it : return f.find(it.rsrc);

   164       tagged ORI   .it : return f.find(it.rsrc);

   165       tagged XORI  .it : return f.find(it.rsrc);

   166       

   167       tagged LUI   .it : return f.find(it.rdst);  //this rds/wrs itself

   168       tagged SLL   .it : return f.find(it.rsrc);

   169       tagged SRL   .it : return f.find(it.rsrc);

   170       tagged SRA   .it : return f.find(it.rsrc);

   171       tagged SLLV  .it : return (f.find(it.rsrc) || f.find(it.rshamt));

   172       tagged SRLV  .it : return (f.find(it.rsrc) || f.find(it.rshamt));

   173       tagged SRAV  .it : return (f.find(it.rsrc) || f.find(it.rshamt));

   174       tagged ADDU  .it : return (f.find(it.rsrc1) || f.find2(it.rsrc2));

   175       tagged SUBU  .it : return (f.find(it.rsrc1) || f.find2(it.rsrc2));

   176       tagged AND   .it : return (f.find(it.rsrc1) || f.find2(it.rsrc2));

   177       tagged OR    .it : return (f.find(it.rsrc1) || f.find2(it.rsrc2));

   178       tagged XOR   .it : return (f.find(it.rsrc1) || f.find2(it.rsrc2));

   179       tagged NOR   .it : return (f.find(it.rsrc1) || f.find2(it.rsrc2));

   180       tagged SLT   .it : return (f.find(it.rsrc1) || f.find2(it.rsrc2));

   181       tagged SLTU  .it : return (f.find(it.rsrc1) || f.find2(it.rsrc2));

   182    

   183 

   184       // -- Branches --------------------------------------------------

   185     

   186       tagged BLEZ  .it : return (f.find(it.rsrc));

   187       tagged BGTZ  .it : return (f.find(it.rsrc));

   188       tagged BLTZ  .it : return (f.find(it.rsrc));

   189       tagged BGEZ  .it : return (f.find(it.rsrc));

   190       tagged BEQ   .it : return (f.find(it.rsrc1) || f.find2(it.rsrc2));

   191       tagged BNE   .it : return (f.find(it.rsrc1) || f.find2(it.rsrc2));

   192       

   193       // -- Jumps -----------------------------------------------------

   194       

   195       tagged J     .it : return False;

   196       tagged JR    .it : return f.find(it.rsrc);

   197       tagged JALR  .it : return f.find(it.rsrc);

   198       tagged JAL   .it : return False;

   199       

   200       // -- Cop0 ------------------------------------------------------

   201       

   202       tagged MTC0  .it : return f.find(it.rsrc);      

   203       tagged MFC0  .it : return False; 

   204 

   205       // -- Illegal ---------------------------------------------------

   206 

   207       default : return False;

   208 

   209     endcase

   210 endfunction

   211 //-----------------------------------------------------------

   212 // Reference processor

   213 //-----------------------------------------------------------

   214 

   215 

   216 //(* doc = "synthesis attribute ram_style mkProc distributed;" *)

   217 //(* synthesize *)

   218 

   219 module  [CONNECTED_MODULE] mkProc( Proc );

   220 

   221    //-----------------------------------------------------------

   222    // State

   223 

   224    // Standard processor state

   225    

   226    Reg#(Addr)  pc    <- mkReg(32'h00001000);

   227    Reg#(Epoch) epoch <- mkReg(0);

   228    Reg#(Stage) stage <- mkReg(PCgen);

   229    BRFile      rf    <- mkBRFile;

   230 

   231    // Branch Prediction

   232    BranchPred               bp <- mkBranchPred();

   233    FIFO#(PCStat)        execpc <- mkLFIFO();

   234    

   235    // Pipelines

   236    FIFO#(PCStat)           pcQ <-mkSizedFIFO(3);

   237    SFIFO#(WBResult, Rindx) wbQ <-mkSFIFO(findwbf);

   238 

   239    // NEED TO ADD CAPABILITY FOR RESET (should be able to just say if I get valid in and these are flagged, clear them.

   240    Reg#(Bit#(32)) cp0_tohost   <- mkReg(0);

   241    Reg#(Bit#(32)) cp0_fromhost <- mkReg(0);

   242    Reg#(Bool)     cp0_statsEn  <- mkReg(False);

   243    Reg#(Bool)     cp0_audioEOF <- mkReg(False);  // Register to let code that EOF is reached

   244    Reg#(Bool)     cp0_progComp <- mkReg(False);  // Register to let processor know that the program is complete (as this terminates)

   245     

   246    // Memory request/response state

   247    

   248    FIFO#(InstReq)  instReqQ    <- mkBFIFO1();

   249    FIFO#(InstResp) instRespQ   <- mkFIFO();

   250 

   251    FIFO#(DataReq)  dataReqQ    <- mkBFIFO1();

   252    FIFO#(DataResp) dataRespQ   <- mkFIFO();

   253 

   254    // Audio I/O

   255    FIFO#(AudioProcessorUnit) inAudioFifo <- mkFIFO;

   256    FIFO#(AudioProcessorUnit) outAudioFifo <- mkFIFO;

   257 

   258 

   259    // Statistics state (2010)

   260    //   Reg#(Stat) num_cycles <- mkReg(0);

   261    //   Reg#(Stat) num_inst <- mkReg(0);

   262 

   263    //Or:

   264    // Statistics state

   265    STAT num_cycles <- mkStatCounter(`STATS_PROCESSOR_CYCLE_COUNT);

   266    STAT num_inst <- mkStatCounter(`STATS_PROCESSOR_INST_COUNT);

   267 

   268    //-----------------------------------------------------------

   269    // Rules

   270 

   271    (* descending_urgency = "exec, pcgen" *)

   272    rule pcgen; //( stage == PCgen );

   273       let pc_plus4 = pc + 4;

   274 

   275       traceTiny("mkProc", "pc",pc);

   276       traceTiny("mkProc", "pcgen","P");

   277       instReqQ.enq( LoadReq{ addr:pc, tag:epoch} );

   278       

   279       let next_pc = bp.get(pc);

   280       if (next_pc matches tagged Valid .npc) 

   281 	begin

   282 	   pcQ.enq(PCStat {qpc:pc, qnxtpc:npc, qepoch:epoch});

   283 	   pc <= npc;

   284 	end

   285      else

   286 	 begin

   287 	   pcQ.enq(PCStat {qpc:pc, qnxtpc:pc_plus4, qepoch:epoch});

   288 	   pc <= pc_plus4;

   289 	 end

   290       

   291    endrule

   292 

   293    rule discard (instRespQ.first() matches tagged LoadResp .ld

   294 					      &&& ld.tag != epoch);

   295       traceTiny("mkProc", "stage", "D");

   296       instRespQ.deq();

   297    endrule

   298 

   299    (* conflict_free = "exec, writeback" *)		      

   300    rule exec (instRespQ.first() matches tagged LoadResp.ld

   301 	      &&& (ld.tag == epoch)

   302 	      &&& unpack(ld.data) matches .inst

   303               &&& !stall(inst, wbQ));

   304 

   305       // Some abbreviations

   306       let sext = signExtend;

   307       let zext = zeroExtend;

   308       let sra  = signedShiftRight;

   309       

   310       // Get the instruction

   311       

   312       instRespQ.deq();

   313       Instr inst 

   314       = case ( instRespQ.first() ) matches

   315 	   tagged LoadResp  .ld : return unpack(ld.data);

   316 	   tagged StoreResp .st : return ?;

   317 	endcase;

   318 

   319       // Get the PC info

   320       let instrpc = pcQ.first().qpc;

   321       let pc_plus4 = instrpc + 4;

   322       

   323       Bool branchTaken = False;

   324       Addr newPC = pc_plus4;

   325 

   326       // Tracing

   327       traceTiny("mkProc", "exec","X");

   328       traceTiny("mkProc", "exInstTiny",inst);

   329       traceFull("mkProc", "exInstFull",inst);

   330 

   331       case ( inst ) matches

   332 

   333 	 // -- Memory Ops ------------------------------------------------      

   334 

   335 	 tagged LW .it : 

   336 	    begin

   337                Addr addr = rf.rd1(it.rbase) + sext(it.offset);

   338                dataReqQ.enq( LoadReq{ addr:addr, tag:zeroExtend(it.rdst) } );

   339                wbQ.enq(tagged WB_Load it.rdst);

   340 	    end

   341 

   342 	 tagged SW .it : 

   343 	    begin

   344                Addr addr = rf.rd1(it.rbase) + sext(it.offset);

   345                dataReqQ.enq( StoreReq{ tag:0, addr:addr, data:rf.rd2(it.rsrc) } );

   346                wbQ.enq(tagged WB_Store);

   347 	    end

   348 

   349 	 // -- Simple Ops ------------------------------------------------      

   350 

   351 	 tagged ADDIU .it : 

   352 	    begin

   353 	       Bit#(32) result = rf.rd1(it.rsrc) + sext(it.imm);

   354 	       wbQ.enq(tagged WB_ALU {data:result, dest:it.rdst});

   355 	    end

   356 	 tagged SLTI  .it : wbQ.enq(tagged WB_ALU {dest:it.rdst, data:slt( rf.rd1(it.rsrc), sext(it.imm) )});

   357 	 tagged SLTIU .it : wbQ.enq(tagged WB_ALU {dest:it.rdst, data:sltu( rf.rd1(it.rsrc), sext(it.imm) ) });

   358 	 tagged ANDI  .it : 

   359 	    begin

   360 	       Bit#(32) zext_it_imm = zext(it.imm);

   361 	       wbQ.enq(tagged WB_ALU {dest:it.rdst, data:(rf.rd1(it.rsrc) & zext_it_imm)} );

   362 	    end

   363 	 tagged ORI   .it : 

   364 	    begin

   365 	       Bit#(32) zext_it_imm = zext(it.imm);

   366 	       wbQ.enq(tagged WB_ALU {dest:it.rdst, data:(rf.rd1(it.rsrc) | zext_it_imm)} );

   367 	    end

   368 	 tagged XORI  .it : 

   369 	    begin

   370 	       Bit#(32) zext_it_imm = zext(it.imm);

   371 	       wbQ.enq(tagged WB_ALU {dest: it.rdst, data:(rf.rd1(it.rsrc) ^ zext_it_imm )});

   372 	    end

   373 	 tagged LUI   .it : 

   374 	    begin

   375 	       $display("PROCESSOR Instr LUI\n");

   376 	       Bit#(32) zext_it_imm = zext(it.imm);

   377 	       wbQ.enq(tagged WB_ALU {dest: it.rdst, data:(zext_it_imm << 32'd16) });

   378 	    end

   379 	 

   380 	 tagged SLL   .it : 

   381 	    begin

   382 	       Bit#(32) zext_it_shamt = zext(it.shamt);

   383 	       wbQ.enq(tagged WB_ALU {dest: it.rdst, data:(rf.rd1(it.rsrc) << zext_it_shamt )} );

   384 	    end

   385 	 tagged SRL   .it : 

   386 	    begin

   387 	       Bit#(32) zext_it_shamt = zext(it.shamt);

   388 	       wbQ.enq(tagged WB_ALU {dest: it.rdst, data:(rf.rd1(it.rsrc) >> zext_it_shamt )});

   389 	    end

   390 	 tagged SRA   .it : 

   391 	    begin

   392 	       Bit#(32) zext_it_shamt = zext(it.shamt);

   393 	       wbQ.enq(tagged WB_ALU {dest: it.rdst, data:sra( rf.rd1(it.rsrc), zext_it_shamt )});

   394 	    end

   395 	 tagged SLLV  .it : wbQ.enq(tagged WB_ALU {dest: it.rdst, data:(rf.rd1(it.rsrc) << rshft(rf.rd2(it.rshamt)) )});

   396 	 tagged SRLV  .it : wbQ.enq(tagged WB_ALU {dest: it.rdst, data:(rf.rd1(it.rsrc) >> rshft(rf.rd2(it.rshamt)) )} );

   397 	 tagged SRAV  .it : wbQ.enq(tagged WB_ALU {dest: it.rdst, data:sra( rf.rd1(it.rsrc), rshft(rf.rd2(it.rshamt)) ) });

   398 	 tagged ADDU  .it : wbQ.enq(tagged WB_ALU {dest: it.rdst, data:(rf.rd1(it.rsrc1) + rf.rd2(it.rsrc2) )} );

   399 	 tagged SUBU  .it : wbQ.enq(tagged WB_ALU {dest: it.rdst, data:(rf.rd1(it.rsrc1) - rf.rd2(it.rsrc2) )} );

   400 	 tagged AND   .it : wbQ.enq(tagged WB_ALU {dest: it.rdst, data:(rf.rd1(it.rsrc1) & rf.rd2(it.rsrc2) )} );

   401 	 tagged OR    .it : wbQ.enq(tagged WB_ALU {dest: it.rdst, data:(rf.rd1(it.rsrc1) | rf.rd2(it.rsrc2) )} );

   402 	 tagged XOR   .it : wbQ.enq(tagged WB_ALU {dest: it.rdst, data:(rf.rd1(it.rsrc1) ^ rf.rd2(it.rsrc2) )} );

   403 	 tagged NOR   .it : wbQ.enq(tagged WB_ALU {dest: it.rdst, data:(~(rf.rd1(it.rsrc1) | rf.rd2(it.rsrc2)) )} );

   404 	 tagged SLT   .it : wbQ.enq(tagged WB_ALU {dest: it.rdst, data:slt( rf.rd1(it.rsrc1), rf.rd2(it.rsrc2) ) });

   405 	 tagged SLTU  .it : wbQ.enq(tagged WB_ALU {dest: it.rdst, data:sltu( rf.rd1(it.rsrc1), rf.rd2(it.rsrc2) ) });

   406 

   407 	 // -- Branches --------------------------------------------------

   408 

   409 	 tagged BLEZ  .it : 

   410             if ( signedLE( rf.rd1(it.rsrc), 0 ) )

   411 	       begin

   412 		  newPC = pc_plus4 + (sext(it.offset) << 2);

   413 		  branchTaken = True;

   414 	       end

   415 

   416 	 tagged BGTZ  .it : 

   417             if ( signedGT( rf.rd1(it.rsrc), 0 ) ) 

   418                begin 

   419 		  newPC = pc_plus4 + (sext(it.offset) << 2);

   420 		  branchTaken = True;

   421 	       end

   422 

   423 	 tagged BLTZ  .it : 

   424             if ( signedLT( rf.rd1(it.rsrc), 0 ) )

   425                begin 

   426 		  newPC = pc_plus4 + (sext(it.offset) << 2);

   427 		  branchTaken = True;

   428 	       end

   429 		  

   430 	 tagged BGEZ  .it : 

   431             if ( signedGE( rf.rd1(it.rsrc), 0 ) )

   432                begin 

   433 		  newPC = pc_plus4 + (sext(it.offset) << 2);		  

   434 		  branchTaken = True;

   435 	       end

   436 

   437       tagged BEQ   .it : 

   438         if ( rf.rd1(it.rsrc1) == rf.rd2(it.rsrc2) )

   439           begin 

   440 	     newPC = pc_plus4 + (sext(it.offset) << 2);

   441 	     branchTaken = True;

   442 	  end

   443 

   444       tagged BNE   .it : 

   445         if ( rf.rd1(it.rsrc1) != rf.rd2(it.rsrc2) )

   446           begin 

   447 	     newPC = pc_plus4 + (sext(it.offset) << 2);

   448 	     branchTaken = True;

   449 	  end

   450 

   451       // -- Jumps -----------------------------------------------------

   452       

   453       tagged J     .it : 

   454         begin 

   455 	   newPC = { pc_plus4[31:28], it.target, 2'b0 };

   456 	   branchTaken = True;

   457 	end

   458       

   459       tagged JR    .it : 

   460         begin

   461 	   $display("PROCESSOR inst JR\n");  

   462 	   newPC = rf.rd1(it.rsrc);

   463 	   branchTaken = True;

   464 	end

   465 

   466       tagged JAL   .it : 

   467        begin

   468 	  $display("PROCESSOR inst JAL\n");  

   469           wbQ.enq(tagged WB_ALU {dest:31, data:pc_plus4 });

   470           newPC = { pc_plus4[31:28], it.target, 2'b0 };		  

   471 	  branchTaken = True;

   472        end

   473 

   474       tagged JALR  .it : 

   475        begin

   476           wbQ.enq(tagged WB_ALU {dest:it.rdst, data:pc_plus4 });

   477           newPC = rf.rd1(it.rsrc);

   478 	  branchTaken = True;

   479        end

   480 

   481       // -- Cop0 ------------------------------------------------------

   482       

   483       tagged MTC0  .it : //Recieve things from host computer

   484 	 begin

   485 	    $display( " PROCESSOR MTC0 call\n");

   486             case ( it.cop0dst )

   487 	       5'd10 : cp0_statsEn <= unpack(truncate(rf.rd1(it.rsrc)));

   488 	       5'd21 : cp0_tohost  <= truncate(rf.rd1(it.rsrc));

   489 	       5'd26 : cp0_progComp <= unpack(truncate(rf.rd1(it.rsrc))); //states audio program completed and termination okay

   490  	       5'd27 : outAudioFifo.enq(tagged Sample unpack(truncate(rf.rd1(it.rsrc))));  //Bit size is 16 not 32 

   491 	       default :

   492 	       $display( " RTL-ERROR : %m : Illegal MTC0 cop0dst register!" );

   493 	    endcase

   494 	    wbQ.enq(tagged WB_Host 0); //no idea wwhat this actually should be.

   495 	 end

   496 

   497 //this is host stuff?

   498       tagged MFC0  .it :  //Things out

   499 	 begin

   500 	    $display( " PROCESSOR MFC0 call\n");

   501             case ( it.cop0src )

   502 	    // not actually an ALU instruction but don't have the format otherwise

   503                5'd10 : wbQ.enq(tagged WB_ALU {dest:it.rdst, data:zext(pack(cp0_statsEn)) });

   504                5'd20 : wbQ.enq(tagged WB_ALU {dest:it.rdst, data:cp0_fromhost });

   505                5'd21 : wbQ.enq(tagged WB_ALU {dest:it.rdst, data:cp0_tohost   });

   506 	       5'd25 : begin

   507 			  $display( "**** EOF Requested\n ");

   508 			  wbQ.enq(tagged WB_ALU {dest:it.rdst, data:zext(pack(cp0_audioEOF)) });  // Reading clears bit

   509 			  cp0_audioEOF <= False;

   510 		       end

   511 	       5'd28 : begin

   512 			  $display( "***** Reqesting Sample \n");

   513 			  let sample = inAudioFifo.first();        // is this going to cause perf. delay?

   514 			  if (sample matches tagged Sample .audio) // if it is EOF another rule sets the cp0_audioEOF  

   515 	      		     wbQ.enq(tagged WB_ALU {dest:it.rdst, data:zext(pack(audio)) });  // do I need pack?

   516 			  else $display ( "Audio File EOF Reached.  Invalid sample request.");

   517 			  inAudioFifo.deq();

   518 		       end

   519               default : 

   520                 $display( " RTL-ERROR : %m : Illegal MFC0 cop0src register!" );

   521             endcase

   522 	end

   523 

   524       // -- Illegal ---------------------------------------------------

   525 

   526       default : 

   527         $display( " RTL-ERROR : %m : Illegal instruction !" );

   528 

   529     endcase

   530 

   531 //evaluate branch prediction

   532      Addr ppc = pcQ.first().qnxtpc; //predicted branch

   533      if (ppc != newPC) //prediction wrong

   534        begin

   535 	  epoch <= pcQ.first().qepoch + 1;

   536 	  bp.upd(instrpc, newPC); //update branch predictor

   537 	  pcQ.clear();

   538 	  pc <= newPC;

   539        end

   540      else

   541 	pcQ.deq();

   542 

   543     if ( cp0_statsEn )

   544       num_inst.incr();

   545 

   546   endrule

   547 

   548   rule writeback; // ( stage == Writeback );

   549      traceTiny("mkProc", "writeback","W");

   550      

   551 

   552     // get what to do off the writeback queue

   553      wbQ.deq();

   554      case (wbQ.first()) matches

   555 	tagged WB_ALU {data:.res, dest:.rdst} : rf.wr(rdst, res);

   556 	tagged WB_Load .regWr : 

   557 	   begin

   558 	      dataRespQ.deq();

   559 	      if (dataRespQ.first() matches tagged LoadResp .ld)

   560 		rf.wr(truncate(ld.tag), ld.data); // no need to use Rindx from queue?  Duplicate?

   561 	   end

   562 	tagged WB_Store : dataRespQ.deq();

   563 	tagged WB_Host .dat : noAction;

   564      endcase

   565            

   566   endrule

   567 

   568   rule inc_num_cycles;

   569     if ( cp0_statsEn )

   570       num_cycles.incr();

   571   endrule

   572 

   573 

   574  // for now, we don't do anything.

   575 //  rule connectAudioReqResp;

   576 //    $display("rlm: PROCESSOR copies a datum\n");

   577 //    outAudioFifo.enq(inAudioFifo.first());

   578 //    inAudioFifo.deq;

   579 //  endrule

   580 

   581   rule flagAudioEnd (inAudioFifo.first() matches tagged EndOfFile);

   582      $display (" PROCESSOR End Audio Flag Set ");

   583      cp0_audioEOF <= True;

   584      inAudioFifo.deq;

   585   endrule

   586 /*

   587   rule sendAudioEnd (cp0_progComp);

   588      $display (" PROCESSOR Says Program Complete ");

   589      outAudioFifo.enq(tagged EndOfFile);

   590      cp0_progComp <= False;  //only send one.  And functions to reset

   591   endrule

   592 */

   593    

   594   //-----------------------------------------------------------

   595   // Methods

   596 

   597   interface Client imem_client;

   598     interface Get request  = fifoToGet(instReqQ);

   599     interface Put response = fifoToPut(instRespQ);

   600   endinterface

   601 

   602   interface Client dmem_client;

   603     interface Get request  = fifoToGet(dataReqQ);

   604     interface Put response = fifoToPut(dataRespQ);

   605   endinterface

   606 

   607   interface Get statsEn_get = toGet(asReg(cp0_statsEn));

   608 

   609   /*

   610   interface CPUToHost tohost;

   611     method Bit#(32) cpuToHost(int req);

   612       return (case (req)

   613        0: cp0_tohost;

   614        1: pc;

   615        2: zeroExtend(pack(stage));

   616       endcase);

   617     endmethod

   618   endinterface

   619   */

   620    

   621   interface Get sampleOutput = fifoToGet(outAudioFifo);

   622   interface Put sampleInput = fifoToPut(inAudioFifo);

   623 

   624 endmodule

   625
author	punk
date	Wed, 05 May 2010 01:09:09 -0400
parents	0475235d1513
children	4d87fa55a776