// The MIT License

 

 // Copyright (c) 2009 Massachusetts Institute of Technology

 

 // Permission is hereby granted, free of charge, to any person obtaining a copy

 // of this software and associated documentation files (the "Software"), to deal

 // in the Software without restriction, including without limitation the rights

 // to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

 // copies of the Software, and to permit persons to whom the Software is

 // furnished to do so, subject to the following conditions:

 

 // The above copyright notice and this permission notice shall be included in

 // all copies or substantial portions of the Software.

 

 // THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

 // IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

 // FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

 // AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

 // LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

 // OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN

 // THE SOFTWARE.

 

 import Connectable::*;

 import GetPut::*;

 import ClientServer::*;

 import Vector::*;

 import FIFO::*;

 import FixedPoint::*;

 

 //AWB includes

 `include "asim/provides/low_level_platform_interface.bsh"

 `include "asim/provides/soft_connections.bsh"

 `include "asim/provides/common_services.bsh"

 

 // Local includes

 `include "asim/provides/audio_pipe_types.bsh"

 `include "asim/provides/path_types.bsh"

 

 interface Mixer;

    method Action toMixer(AudioStream streamIn);

    interface Get#(AudioProcessorUnit) mainOut;

 endinterface

 

 module [CONNECTED_MODULE]  mkMixer#(Integer numVoices, Vector#(numVoices, Volume) scalars) (Mixer);

 

    function Bool isAudioFini(Vector#(numVoices, Reg#(Bool)) voiceStat);

      Bool result = True;

       for (Integer i = 0; i < numVoices; i = i+1)

         begin

           result = voiceStat[i] && result;

         end

      return result; 

    endfunction

 

 	 

   // Instantiate the modules

    Vector#(numVoices, FIFO#(AudioPipeUnit)) voicesIn <- replicateM(mkFIFO());

 // <- newVector();

    Vector#(numVoices, Reg#(Bool)) voiceFini <- replicateM(mkReg(False));

 

    FIFO#(AudioProcessorUnit) masterFifo <- mkFIFO();

 

    rule sendEnd(isAudioFini(voiceFini));

       masterFifo.enq(tagged EndOfFile);

       //prep for reset

       for (Integer i = 0; i < numVoices; i = i+1)

 	 voiceFini[i] <= False;

    endrule

    

    rule processSample(!isAudioFini(voiceFini));  //implicit on all voiceFifos having data

       FixedPoint#(32,32) sum = 0;  //this should allow 16 voices at 16 bits without messing up

       for (Integer i = 0; i < numVoices; i = i+1)

 	 begin

 	    if (voicesIn[i].first() matches tagged Valid .data)

 	      begin

 		 case (data) matches

 		    tagged Sample .sample :

 	               sum = sum + ((fromInt(sample) * fromInt(scalars[i])) >> 8); 

 	            //shifting right 8 to divide by 256

 		    tagged EndOfFile :

 		       voiceFini[i] <= True;

 		 endcase

 	      end

 	    else voiceFini[i] <= True;

 	    voicesIn[i].deq();

 	 end

       

        masterFifo.enq(tagged Sample truncate(fxptGetInt(sum >> numVoices)));

    endrule

  

   // Internal connections

 

 //   method Action loadMixerFifos(AudioStream voiceInput);

 //      voicesIn[voiceInput.voice].enq(voiceInput.data);

 //   endmethod

  

    method Action toMixer(AudioStream streamIn);

 	 voicesIn[streamIn.voice].enq(streamIn.data);

    endmethod

    

    interface Get mainOut = fifoToGet(masterFifo);

 

 endmodule